RE: schemarama 2

Hey Danny,

I just spent a bit of time reading up on your atomOWL work, nice!

Also nice to see use of skos:editorialNote :)  I'd like to support use of SKOS Core annotation-like properties (skos:prefLabel, skos:altLabel, skos:definition ...) in OWL ontologies, without necessarily going outside OWL DL, I wrote this up as an issue with possible solution at [3], any comments welcome.

I don't know atom well enough to know what 'constraints' you want to express, but here's a few examples from the SKOS Core thesaurus test case [1] you might find handy ...

For SKOS Core there is a need to express 'constraints' that are contingent upon values of language tags in literals, e.g. 'no concept should have more than one preferred label per language'.  The Schemarama 2 test looks like:

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX : <http://purl.org/net/schemarama#>
CONSTRUCT
{
	[] a :Error;
		:message 'Resource [1] has more than one preferred lexical label [2][3] in a given language.';
		:implicated ( ?x ?l ?m );
	.
}
WHERE
{
	?x skos:prefLabel ?l; skos:prefLabel ?m.
	FILTER ( str(?l) != str(?m) && lang(?l) = lang(?m) )
}

Checking whether some statements are absent is a bit less obvious to express using SPARQL, and made me think.  The following checks whether, for some concept that has no broader concepts in the same scheme, you have also stated that the concept is a top concept:

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX : <http://purl.org/net/schemarama#>
CONSTRUCT
{
	[] a :Warning;
		:message 'Concept [1] has no broader in scheme [2], and is not declared as top concept for this scheme.';
		:implicated ( ?x ?s );
	.
}
WHERE
{
	?x skos:inScheme ?s.
	OPTIONAL 
	{ 
		?x skos:broader ?y.
		?y skos:inScheme ?s.
	}.
	OPTIONAL
	{
		?s skos:hasTopConcept ?z.
		FILTER ( ?z = ?x )
	}.
	FILTER ( !bound(?y) && !bound(?z) )
}

Hope that helps.

Btw feel free to write test cases and run them on the Schemarama 2 test service [2].

Cheers,

Al.

[1] http://isegserv.itd.rl.ac.uk/cvs-public/~checkout~/skos/schemarama/thesaurus.turtle
[2] http://isegserv.itd.rl.ac.uk/schemarama/
[3] http://www.w3.org/2004/02/skos/core/proposals#owlImport-7

> -----Original Message-----
> From: Danny Ayers [mailto:danny.ayers@gmail.com]
> Sent: 02 November 2005 09:46
> To: Miles, AJ (Alistair)
> Cc: semantic-web@w3.org
> Subject: Re: schemarama 2
> 
> 
> On 11/1/05, Miles, AJ (Alistair) <A.J.Miles@rl.ac.uk> wrote:
> 
> > http://isegserv.itd.rl.ac.uk/schemarama/
> 
> Wonderful.
> 
> I'd be interested in hearing your thoughts on how suitable this
> approach might be with Atom/OWL [1]. This is basically the Atom
> syndication modelled in RDF/OWL (work in progress, expect a
> request-for-feedback post to list sometime soon). There is already a
> lot of scope with Atom for validation at the syntax level, but I've
> been playing a little with validation at the model level using OWL
> constraints (some notes at [2]). I anticipate this will be pretty
> limited compared to the syntax stuff, but thought it could be useful
> for ensuring some level of sanity for Atom data when in the RDF/OWL
> world. (A particular variety of app I envisage is an Atom Store built
> on a triplestore, so it would have sources/sinks of Atom
> format/protocol). If I understand correctly, the Schemarama approach
> could take this even further towards the constraints given in the Atom
> spec. Does that make sense?
> 
> Cheers,
> Danny.
> 
> [1] http://atomowl.org/
> [2] 
http://dannyayers.com/archives/2005/10/18/atomowl-ontology-testing/




--

http://dannyayers.com

Received on Wednesday, 2 November 2005 15:41:13 UTC