- From: James Clark <jjc@jclark.com>
- Date: Tue, 14 Aug 2012 20:49:25 +0700
- To: public-microxml@w3.org
The grammar at http://www.w3.org/community/microxml/wiki/Initial_Status
has been stable for some time now. Does anybody want to propose
_removing_ anything from this? If not, then I propose we start
considering what, if anything, we want to add to this. I suggest we
use a separate thread for each possible addition.
For reference, here it is again:
# Documents
document ::= s element s
# Elements
element ::= startTag content endTag
content ::= (element | dataChar | charRef)*
startTag ::= '<' name (s+ attribute)* s* '>'
endTag ::= '</' name s* '>'
# Attributes
attribute ::= name s* '=' s* attributeValue
attributeValue ::= '"' ((dataChar - '"') | charRef)* '"'
| "'" ((dataChar - "'") | charRef)* "'"
# Data characters
dataChar ::= char - ('<' | '&' | '>')
# Character references
charRef ::= hexCharRef | namedCharRef
hexCharRef ::= '&#x' [0-9a-fA-F]+ ';'
namedCharRef ::= '&' charName ';'
charName ::= 'amp' | 'lt' | 'gt' | 'quot' | 'apos'
# Names
name ::= nameStartChar nameChar*
nameStartChar ::= [A-Z] | [a-z] | "_"
nameChar ::= nameStartChar | [0-9] | "-" | "."
# White space
s ::= #x9 | #xA | #xD | #x20
# Characters
char ::= s | ([#x21-#x10FFFF] - forbiddenChar)
forbiddenChar ::= surrogateChar | #FFFE | #FFFF
surrogateChar ::= [#xD800-#xDFFF]
James
Received on Tuesday, 14 August 2012 13:50:17 UTC