- From: Peter DeVries <pete.devries@gmail.com>
- Date: Thu, 9 Sep 2010 17:45:18 -0500
- To: Richard Cyganiak <richard@cyganiak.de>, public-lod@w3.org
- Message-ID: <AANLkTin6NP7v3vr0Z96Ah3FD+fnDA4adx9=ORkYKBsoR@mail.gmail.com>
Hi Richard,
I made a slightly different version after looking though my link outs in the
RDF.
There are probably other predicates that link out but this should be the
majority of them.
---
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX txn: <http://lod.taxonconcept.org/ontology/txn.owl#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX umbel: <http://umbel.org/umbel#>
SELECT ?domain_s ?domain_o (COUNT(*) AS ?count)
WHERE {
{
SELECT (bif:regexp_substr("http://([^/]*)", STR(?s), 1) AS ?domain_s)
(bif:regexp_substr("http://([^/]*)", STR(?o), 1) AS ?domain_o)
WHERE {
{ ?s owl:sameAs ?o }
UNION
{ ?s skos:exactMatch ?o }
UNION
{ ?s skos:broadMatch ?o }
UNION
{ ?s skos:narrowMatch ?o }
UNION
{ ?s skos:relatedMatch ?o }
UNION
{ ?s skos:closeMatch ?o }
UNION
{ ?s txn:speciesConceptHasSpeciesNameString ?o }
UNION
{ ?s txn:speciesNameStringHasSpeciesTaxonConcept ?o }
UNION
{ ?s txn:speciesConceptHasBasionymNameString ?o }
UNION
{ ?s txn:basionymNameStringHasSpeciesTaxonConcept ?o }
UNION
{ ?s txn:hasPDFVersion ?o }
UNION
{ ?s txn:hasAuthorURI ?o }
UNION
{ ?s foaf:page ?o }
UNION
{ ?s foaf:topic ?o }
UNION
{ ?s txn:inDBpediaClade ?o }
UNION
{ ?s txn:occurrenceInContinent ?o }
UNION
{ ?s txn:occurrenceInStateProvince ?o }
UNION
{ ?s txn:occurrenceInCounty ?o }
}
}
}
GROUP BY ?domain_s ?domain_o
--
This query on the latest TaxonConcept.org RDF gives the following:
*domain_s* *domain_o* *count*
lod.geospecies.org lod.taxonconcept.org 71143
www.uniprot.org lod.taxonconcept.org 21570
bio2rdf.org lod.taxonconcept.org 21570
dbpedia.org lod.taxonconcept.org 18790
eunis.eea.europa.eu lod.taxonconcept.org 2986
www.bbc.co.uk lod.taxonconcept.org 318
lod.taxonconcept.org lod.geospecies.org 71142
lod.taxonconcept.org www.uniprot.org 21570
lod.taxonconcept.org bio2rdf.org 21799
lod.taxonconcept.org dbpedia.org 94441
lod.taxonconcept.org eunis.eea.europa.eu 5972
lod.taxonconcept.org www.bbc.co.uk 636
rdf.freebase.com lod.taxonconcept.org 118
lod.taxonconcept.org 72
lod.taxonconcept.org rdf.freebase.com 118
lod.taxonconcept.org 24902
sw.opencyc.org lod.taxonconcept.org 23
lod.taxonconcept.org sw.opencyc.org 23
lod.taxonconcept.org gni.globalnames.org 72687
gni.globalnames.org lod.taxonconcept.org 72687
lod.taxonconcept.org www.americanarachnology.org 1
lod.taxonconcept.org assets.geospecies.org 3
lod.taxonconcept.org www.itis.gov 42097
lod.taxonconcept.org data.gbif.org 1152
lod.taxonconcept.org bugguide.net 3296
lod.taxonconcept.org www.eol.org 516
lod.taxonconcept.org en.wikipedia.org 18790
lod.taxonconcept.org species.wikimedia.org 9309
lod.taxonconcept.org www.boldsystems.org 39
lod.taxonconcept.org www.catalogueoflife.org 53
lod.taxonconcept.org lod.taxonconcept.org 284592
lod.taxonconcept.org mushroomobserver.org 5
assets.geospecies.org lod.geospecies.org 10
assets.geospecies.org lod.taxonconcept.org 1
assets.geospecies.org media.geospecies.org 5
static.flickr.com www.flickr.com 33
bugguide.net lod.taxonconcept.org 3245
media.geospecies.org lod.taxonconcept.org 19
ocs.geospecies.org lod.taxonconcept.org 26
media.geospecies.org dbpedia.org 14
assets.geospecies.org dbpedia.org 1
media.geospecies.org lod.geospecies.org 37
mushroomobserver.org lod.taxonconcept.org 5
media.geospecies.org media.geospecies.org 29
ocs.geospecies.org ocs.geospecies.org 53
media.geospecies.org assets.geospecies.org 15
media.geospecies.org static.flickr.com 2
bugguide.net bugguide.net 1
mushroomobserver.org mushroomobserver.org 3
bugguide.net dbpedia.org 2
mushroomobserver.org dbpedia.org 1
ocs.geospecies.org sws.geonames.org 39
- Pete
On Thu, Sep 9, 2010 at 4:18 PM, Peter DeVries <pete.devries@gmail.com>wrote:
> Hi Richard,
>
> You appear to be correct about versions. The public site is running the
> ubuntu package which is a little order.
>
> I have a private instance that is running the compiled version and that
> does not have a problem with the AS.
>
> I am updating the data set on that machine so that the two match and then
> will run the query you sent to get the latest info.
>
> Thanks!
>
> - Pete
>
>
> On Thu, Sep 9, 2010 at 10:39 AM, Richard Cyganiak <richard@cyganiak.de>wrote:
>
>> Peter,
>>
>>
>> On 9 Sep 2010, at 02:54, Peter DeVries wrote:
>>
>>> I was wondering if anyone has figured out a way to generate the LOD
>>> interlinking (InLinks/OutLinks) stats from a Virtuoso OpenSource SPARQL
>>> Endpoint.
>>>
>>
>> I used this one here a lot. It makes use of Viruoso's awesome built-in
>> function library. Unfortunately it doesn't work on your endpoint, complains
>> about the AS in the SELECT clause. Old Virtuoso version?
>>
>> Richard
>>
>>
>>
>> PREFIX owl: <http://www.w3.org/2002/07/owl#>
>> PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
>> SELECT ?domain_s ?domain_o (COUNT(*) AS ?count)
>> WHERE {
>> {
>> SELECT (bif:regexp_substr("http://([^/]*)", STR(?s), 1) AS
>> ?domain_s) (bif:regexp_substr("http://([^/]*)", STR(?o), 1) AS ?domain_o)
>> WHERE {
>> { ?s owl:sameAs ?o }
>> UNION
>> { ?s skos:exactMatch ?o }
>> UNION
>> { ?s skos:broadMatch ?o }
>> UNION
>> { ?s skos:narrowMatch ?o }
>> UNION
>> { ?s skos:relatedMatch ?o }
>> UNION
>> { ?s skos:closeMatch ?o }
>> }
>> }
>> }
>> GROUP BY ?domain_s ?domain_o
>>
>>
>>
>>
>>> The two named graphs I am most interested in are:
>>>
>>> <urn:org:linkedopenspeciesdata:dataspace:taxonconcept> *taxonconcept*
>>> <urn:org:linkedopenspeciesdata:dataspace:geospecies> *geospecies*
>>> *
>>> *
>>> On this endpoint http://lsd.taxonconcept.org/sparql
>>>
>>> Thanks!
>>>
>>> - Pete
>>>
>>> ----------------------------------------------------------------
>>> Pete DeVries
>>> Department of Entomology
>>> University of Wisconsin - Madison
>>> 445 Russell Laboratories
>>> 1630 Linden Drive
>>> Madison, WI 53706
>>> TaxonConcept Knowledge Base <http://www.taxonconcept.org/> / GeoSpecies
>>> Knowledge Base <http://lod.geospecies.org/>
>>> About the GeoSpecies Knowledge Base <http://about.geospecies.org/>
>>> ------------------------------------------------------------
>>>
>>
>>
>
>
> --
> ----------------------------------------------------------------
> Pete DeVries
> Department of Entomology
> University of Wisconsin - Madison
> 445 Russell Laboratories
> 1630 Linden Drive
> Madison, WI 53706
> TaxonConcept Knowledge Base <http://www.taxonconcept.org/> / GeoSpecies
> Knowledge Base <http://lod.geospecies.org/>
>
> About the GeoSpecies Knowledge Base <http://about.geospecies.org/>
> ------------------------------------------------------------
>
--
----------------------------------------------------------------
Pete DeVries
Department of Entomology
University of Wisconsin - Madison
445 Russell Laboratories
1630 Linden Drive
Madison, WI 53706
TaxonConcept Knowledge Base <http://www.taxonconcept.org/> / GeoSpecies
Knowledge Base <http://lod.geospecies.org/>
About the GeoSpecies Knowledge Base <http://about.geospecies.org/>
------------------------------------------------------------
Received on Thursday, 9 September 2010 22:45:53 UTC