Re: [csswg-drafts] [css-shapes-2] `curve to` keyword `using` seems a bit off (#10649)

Thanks @SebastianZ! With the `arc` changes, I think it should look like this:

```
shape() = shape( <'fill-rule'>? from <coordinate-pair>, <shape-command># )

<shape-command> = <move-command> | <line-command> | <horizontal-line-command> |
                  <vertical-line-command> | <curve-command> | <smooth-command> | <arc-command> | close

<coordinate-pair> = <length-percentage>{2}
<relative-control-point> = <coordinate-pair> [ from [ start | end | origin ] ]?
<to-control-point> = [ <position> | <relative-control-point> ]

<move-command> = move [ to <position> | by <coordinate-pair> ]
<line-command> = line [ to <position> | by <coordinate-pair> ]
<horizontal-line-command> = hline [ to [ <length-percentage> | left | center | right | x-start | x-end ] | by <length-percentage> ]
<vertical-line-command> = vline [ to [ <length-percentage> | top | center | bottom | y-start | y-end ] | by <length-percentage> ]
<curve-command> = curve [ to <position> with <to-control-point> [ / <to-control-point> ]?
                        | by <coordinate-pair> with <relative-control-point> [ / <relative-control-point> ]? ]
<smooth-command> = smooth [ to <position> [ with <to-control-point> ]?
                          | by <coordinate-pair> [ with <relative-control-point> ]? ]
<arc-command> = arc [ to <position> | by <coordinate-pair> ] 
                                      && of <length-percentage>{1,2}
                                      && <arc-sweep>?
                                      && <arc-size>?
                                      && [rotate <angle>]?
]
```                


-- 
GitHub Notification of comment by noamr
Please view or discuss this issue at https://github.com/w3c/csswg-drafts/issues/10649#issuecomment-2426552611 using your GitHub account


-- 
Sent via github-notify-ml as configured in https://github.com/w3c/github-notify-ml-config

Received on Monday, 21 October 2024 12:37:33 UTC