acre

     ∇ r←BS
[1]    r←⎕UCS 8 ⍝ back space
     ∇

     ∇ r←CR
[1]    r←⎕UCS 13 ⍝ carriage return
     ∇

     ∇ r←HT
[1]    r←⎕UCS 9 ⍝ horizonal tab
     ∇

     ∇ Ia←{⍺←⊢
[1]        (⎕A,¨1↓¨⊢)ia''
[2]   ⍝ ICAO (International Civil Aviation Organization) Alphabet
[3]    }
     ∇

     ∇ r←LF
[1]    r←⎕UCS 10 ⍝ line feed
     ∇

     ∇ r←NB
[1]    r←⎕UCS 160 ⍝ non-breaking space
     ∇

     ∇ r←NL
[1]    r←⎕UCS 133 ⍝ next line
     ∇

     ∇ r←TC ⍝ terminal control?
[1]    r←HT LF CR NL
     ∇

     ∇ r←_Desc
[1]    r←2 2↓⎕CR⊃⎕SI
[2]   ⍝ UT
[3]   ⍝
[4]   ⍝ This ns contains the (fairly) definitive editions of a number of the most
[5]   ⍝ useful or demonstrative functions and operators I've written plus a number
[6]   ⍝ of things added which may be more specific to the workspace in which it
[7]   ⍝ currently resides.
[8]   ⍝
[9]   ⍝ I didn't originate them all.
[10]  ⍝
[11]  ⍝ Though I hope at least some of them are better than an original I might have
[12]  ⍝ found.
[13]  ⍝
[14]  ⍝ Some don't actually get used much if at all but I'll often cut and paste
[15]  ⍝ algorithms into application code.
[16]  ⍝
[17]  ⍝ Not all of them are necessarily the fasted way of doing whatever has to be done
[18]  ⍝ but if not I hope elegance or clarity might make up for it.
[19]  ⍝
[20]  ⍝ To avoid unneccessarily many assignments the functions and operators in this ns
[21]  ⍝ are either written to be origin and/or APL2 compatibility independent or assume
[22]  ⍝ ⎕IO←0 and ⎕ML←0
     ∇

     ∇ aa←{⍺←⊢
[1]        ⍵{⊣/⍵⌽'&',⍪⍵\⍺}{(1+⍳⌈/⍵)∊⍵}+\1+<\~(1 cc ⍵)∊1 cc{⍵/⍨¯1⌽⍵='&'}⊃,/⍺
[2]   ⍝ ⍺ extant captions
[3]   ⍝ ⍵ new caption
[4]   ⍝ ← new caption with (or without) &
[5]   ⍝ add accelerator ampersand to new caption ⍵ given extant captions ⍺
[6]    }
     ∇

     ∇ ab←{
[1]        ~∘' '~∘⍵{⍵/⍨0≤⎕NC'_',,[⍬]⍵}⎕UCS⍳256
[2]   ⍝ alphabet (inc. ⎕D)
[3]   ⍝ ⍵ string
[4]   ⍝ ← legal name elements without ⍵
[5]    }
     ∇

     ∇ af←{
[1]        ⍺{(⎕NUNTIE ⍵)⊢⍺ ⎕NAPPEND ⍵,⎕DR ⍺}{
[2]            22::⍵ ⎕NTIE 0
[3]            ⍵ ⎕NCREATE 0
[4]        }⍵
[5]   ⍝ append file
[6]   ⍝ ⍺ data in form it can be written as-is - char or num vec
[7]   ⍝ ⍵ file path/name if not exists is created first
[8]   ⍝ ← bytes written
[9]   ⍝ Phil Last ⍝ 2011-09-12 12:00
[10]   }
     ∇

     ∇ al←{
[1]        ⍺←2 ⋄ on off←⍺
[2]        len←⊃⍴/⍴txt←⎕FMT↑⍵                ⍝ this
[3]        code rem←⊂[1+⍳2](∨\(txt⍷⍨on 1/' ⍝')>≠\txt='''')⊖↑txt' ' ⍝ not this
[4]        (msk/len)←{0⌈⌈/+/∨\⌽' '∨.≠⍵}code⌿⍨msk←rem∨.≠' '
[5]        rem←⊃,/(off⍴' '),⊂rem⌽⍨+/∧\rem=' '     ⍝ this
[6]        {⍵/⍨⌽∨\⌽' '∨.≠⍵}↑(len↑¨↓code),¨↓rem
[7]   ⍝ align
[8]   ⍝ ⍺ on off - (minimum blanks to adjust),(minimum offset for alignment)
[9]   ⍝ ⍵ text array - presumed to be a ⎕cr
[10]  ⍝ ← (⍵) with aligned comments
[11]  ⍝ Phil Last ⍝ 2008-09-10 08:26
[12]   }
     ∇

     ∇ an←{
[1]        ↑∪↓{
[2]            (2=⍴⍵):2 2⍴⍵,⌽⍵
[3]            ⊃⍪/⍵,∘∇¨↓{
[4]                ⍵⍴⍨0 ¯1+⍴⍵
[5]            }⌽⍵
[6]        }⍵
[7]   ⍝ anagrams
[8]   ⍝ ⍵ string
[9]   ⍝ ← anagrams
[10]  ⍝ Phil Last ⍝ 2008-01-28 19:02
[11]   }
     ∇

     ∇ ar←{
[1]        req←~∘∊⍨' 'sl⍕⍺
[2]        22::0 ⍝ missing file
[3]        tie←⍵ ⎕FSTIE 0
[4]        dct←⎕FREAD tie,1
[5]        0∊⍴req:dct⊣⎕FUNTIE tie
[6]        cmp←2+dct⍳nms←(⍺≡'*')⊃req dct
[7]        0∊⍴cmp:⎕NS''⊣⎕FUNTIE tie
[8]        20::⎕SIGNAL/⌽⎕EN,⎕DM⊣⎕FUNTIE tie ⍝ file index error
[9]        (⎕FUNTIE tie)⊢dx nms{⍺ ⍵}⎕FREAD tie cmp
[10]  ⍝ associative file read - see also aw
[11]  ⍝ ⍺ required names | '*' for all | '' for names
[12]  ⍝ ⍵ filename - component 1 is names. following are the associated values.
[13]  ⍝ ← dictionary with named vars | 0∊⍴⍺: names | file missing: 0
[14]   }
     ∇

     ∇ aw←{
[1]        dict←⍺
[2]        file←⍵
[3]        data←dict.({(⊂⍵),1↓⍎¨'0',⍵}⎕NL-2)
[4]        (old new)←{file,⍵,,'K-6F15.6'⎕FMT 100⊥6⍴⎕TS}¨'.OLD.' '.NEW.'
[5]        newt←{⍵⊣⍺ ⎕FAPPEND ⍵}/(⌽data),new ⎕FCREATE 0
[6]        ok←×oldt←{22::0 ⋄ old ⎕FRENAME file ⎕FTIE 0}0
[7]        newt←⎕FUNTIE file ⎕FRENAME newt ⍝ ok!
[8]        oldt←old∘⎕FERASE⍣ok⊢oldt
[9]        file
[10]  ⍝ associative file write - see also ar
[11]  ⍝ ⍺  Dictionary - named vars that become the entire contents of new file.
[12]  ⍝ ⍵  Filename - original safely renamed if extant and removed afterwards.
[13]  ⍝ ←  ⍵
[14]  ⍝ Component one is names. Following are the associated values each in the
[15]  ⍝ component numbered two more than the index of its name in component one
[16]  ⍝ Temp filenames are original with 'OLD', or 'NEW', and the current time.
[17]  ⍝ as: original.ext.OLD.20120322.113716; original.ext.NEW.20120322.113716.
[18]   }
     ∇

     ∇ ay←{⍺←⊢
[1]        drop←{⍵/⍨∨\' '∨.≠⍵}
[2]        p3←({⍵⊣⍵.⎕ML←3}⎕NS'').⊂
[3]        words←{(' '≠⍵)p3 ⍵}
[4]        ctl←⊣/src←drop(0,⍴,⍵)↓⍵{⍵⌿⍨>/⍺⍷⍵}⎕CR 1⊃⎕XSI
[5]        dat←{(+/∨\' '≠⌽⍵)↑¨↓⍵}drop 0 1↓src⌿⍨ctl←ctl=type←⊃ctl~' '
[6]        ctl/⍨←(∨\ctl)∧⌽∨\⌽ctl
[7]        (ctl dat)←⊃{d←⍺ p3 ⍺\⍵
[8]            c←{⍵/⍨~0 1⍷⍵}⍺/⍨~1 1⍷⍺
[9]            ⊃∘(∇/)⍣(0∊c)⊢c d
[10]       }/ctl dat
[11]       type='d':dat                         ⍝ text depth vs rank
[12]       dat←{⍵⍴⍨(⍴⍵)↓⍨+/∧\1=⍴⍵}↑⍣(≡dat)⊢dat  ⍝ convert depth to rank
[13]       type='t':dat                         ⍝ text
[14]       type='n':↑1∘⊃∘⎕VFI¨↓dat              ⍝ numeric
[15]       type='x':mx(⍺⊣#).⍎¨↓dat              ⍝ executable
[16]       type='w':~∘' '¨↑words¨↓dat           ⍝ words
[17]       type='m':⊃(~∘' '¨↑words¨↓dat){(⍴⍺)⍴⍺⊖↑⍺⍺ ⍵}/⊂rk ¯1↑⍉↑⍉⎕VFI¨↓dat
[18]       1:dat                                ⍝ ↑ mixed words and numbers
[19]  ⍝ ⍺  space (dflt #) in which 'x' type source expressions are executed
[20]  ⍝ ⍵  substring to identify source rows to use in caller.
[21]  ⍝    source rows not preceded by first type char are rank indicators -
[22]  ⍝    - as inserted blank rows in default output.
[23]  ⍝ ←  array represented by selected source rows in caller.
[24]   }
     ∇

     ∇ b64←{
[1]   ⍝    A←⎕A,(⎕UCS(⍳26)+⎕UCS'a'),⎕D,'+/'                      ⍝ alphabet
[2]        A←'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/'
[3]        ⍺←~∧/⍵∊A,'='
[4]        ed←{⊃⍵{⍺{2⊥⍉((⌈(⍴⍵)÷⍺),⍺){⍺⍴(×/⍺)↑⍵}⍵},⍉(⍵⍴2)⊤⍺⍺}/⍺}  ⍝ encode decode
[5]        ⍺:{⍵,'='⍴⍨4|-⍴⍵}(⊂6 8 ed ⎕UCS ⍵)⌷A                    ⍝ encode strict /
[6]        ⍺:(⊂6 8 ed ⎕UCS ⍵)⌷A                                  ⍝ encode lax    x
[7]        1:⎕UCS{x↓8 6 ed A⍳⍵,'='↑⍨x←-4|-⍴⍵}⍵∩A                 ⍝ decode lax    /
[8]        1:⎕UCS{(-+/'='=¯3↑⍵)↓8 6 ed A⍳⍵}⍵∩A,'='               ⍝ decode strict x
[9]   ⍝ base64 encoding
[10]  ⍝ ⍺ 1=encode; 0=decode
[11]  ⍝ ⍵ byte string: 256∧.>⎕ucs ⍵
[12]  ⍝ ← ⍺=1: longer (4:3) string in A-Z,a-z,0-9,+/= only
[13]  ⍝   ⍺=0: original string whence ⍵ was encoded
[14]  ⍝   whitespace in (⍵) is ignored on decode
[15]   }
     ∇

     ∇ bc←{
[1]        ⍵/⍨⌽∨\⌽' '∨.≠⍵
[2]   ⍝ blank column removal
[3]   ⍝ ⍵ 2d text array
[4]   ⍝ ← (⍵) without trailing blank columns
[5]   ⍝ Phil Last ⍝ 2008-01-24 18:00
[6]    }
     ∇

     ∇ bf←{⍺←⊢
[1]        r←⎕FMT↑⍵
[2]        b←r∊⍺⊣'.'
[3]        m←⍉4⊥⍉2⊥↑↑(3,/0,b,0)(3,⌿0⍪b⍪0)
[4]        c←'│  ─  ┌  │  │  └  ├  ─  ┐  ─  ┬  ┘  ┤  ┴  ┼ .'~' '
[5]        n←13 14 15 28 29 30 31 44 45 46 47 60 61 62 63
[6]        (⍴r)⍴(m∊n)⊖(2,⍴r)⍴r⍪(⊂n⍳m)⌷c
[7]   ⍝ box frame
[8]   ⍝ [⍺] char(s) to be replaced - dflt '.'
[9]   ⍝  ⍵  char array
[10]  ⍝  ←  array with ⍺ replaced by boxing chars
[11]  ⍝ ┌───┬───┬───┬───┬───┬───┬───┬───┐  ┌───┬───┬───┬───┬───┬───┬───┬───┐
[12]  ⍝ │   │ ∘ │   │ ∘ │   │ ∘ │   │ ∘ │  │   │ │ │   │ │ │   │ │ │   │ │ │
[13]  ⍝ │ ∘ │ ∘ │ ∘∘│ ∘∘│ ∘ │ ∘ │ ∘∘│ ∘∘│  │ ∘ │ │ │ ──│ └─│ │ │ │ │ ┌─│ ├─│
[14]  ⍝ │   │   │   │   │ ∘ │ ∘ │ ∘ │ ∘ │  │   │   │   │   │ │ │ │ │ │ │ │ │
[15]  ⍝ ├───┼───┼───┼───┼───┼───┼───┼───┤  ├───┼───┼───┼───┼───┼───┼───┼───┤
[16]  ⍝ │   │ ∘ │   │ ∘ │   │ ∘ │   │ ∘ │  │   │ │ │   │ │ │   │ │ │   │ │ │
[17]  ⍝ │∘∘ │∘∘ │∘∘∘│∘∘∘│∘∘ │∘∘ │∘∘∘│∘∘∘│  │── │─┘ │───│─┴─│─┐ │─┤ │─┬─│─┼─│
[18]  ⍝ │   │   │   │   │ ∘ │ ∘ │ ∘ │ ∘ │  │   │   │   │   │ │ │ │ │ │ │ │ │
[19]  ⍝ └───┴───┴───┴───┴───┴───┴───┴───┘  └───┴───┴───┴───┴───┴───┴───┴───┘
[20]  ⍝ Phil Last 2016-02-12
[21]   }
     ∇

     ∇ bs←{⍺←⊢
[1]        1↓{
[2]            scr←(⊂''),{11 16::js ⍵ ⋄ ⎕SRC ⍵}⍵
[3]            (¯1↓scr),('   '∘,¨⊃,/(⊂''),∇ ea ⍵{⍵/⍨⍺={⍵.##}ea ⍵}{⍵/⍨~'['∊∘⍕¨⍵}⍵.⍎ea↓⍵.⎕NL 9.1 9.4),⊢/scr
[4]        }⍵
[5]   ⍝ build script from space ⍵
[6]   ⍝ see js
[7]    }
     ∇

     ∇ bx←{
[1]        ⍺←⊢
[2]        (3 3⍴⍺⊃'.-.| |''-''' '┌─┐│ │└─┘'){
[3]            (' ',' '⍪⍵){(⍴⍵)⍴(⍵≠' ')⊖↑⍺ ⍵}⊃⍺{1 ⍺ 1⌿1 ⍵ 1/⍺⍺}/⍴⍵
[4]        }⎕FMT ⍵
[5]   ⍝ box
[6]   ⍝ Phil Last ⍝ 2008-01-23 13:35
[7]    }
     ∇

     ∇ by←{
[1]        ⍺←#
[2]        ⍵{⍵/⍨∨/⍺⍷⍕⎕AT ⍵}⍺ li 3.1 3.2 4.1 4.2
[3]   ⍝ saved by
[4]   ⍝ ⍺ space
[5]   ⍝ ⍵ potential "Last saved by:" (⎕AN)
[6]   ⍝ ← fns ops in or below ⍺ last saved by ⍵
[7]   ⍝ Phil Last ⍝ 2008-01-10 09:41
[8]    }
     ∇

     ∇ c2←{
[1]        c2←{
[2]            ¯1↓¨2⍴⊃{
[3]                l r m←⍵
[4]                ((⍴m)<x←1+m⍳⍺):(l,1)(r,0)m
[5]                (l,1↑⍨-x)(r,x⍴1)(x↓m)
[6]            }/(⊂¨⌽⍺,⊂⍺ ⍵),⊂⍬ ⍬(⍵,⊂⍺ ⍵)
[7]        }
[8]        ⍺←⊢
[9]        ⊃{(⍺ c2 ⍵){⍺ ⍵⊃⍨(⍴⊃⍺)>⍴⊃⍵}⌽(⍵ c2 ⍺)}/⍺ ⍵
[10]  ⍝ compare two lists
[11]  ⍝ ⍺ list presumed to be related to ⍵
[12]  ⍝ ⍵ list presumed to be related to ⍺
[13]  ⍝ [monad: ⍵ is two lists]
[14]  ⍝ ← two expansion lists to accomodate mis-matches
[15]  ⍝ Phil Last ⍝ 2008-07-17 21:28
[16]   }
     ∇

     ∇ c3←{
[1]        c3←{
[2]            a b c←⍵
[3]            xa xb←a c2 b
[4]            xxa xc←(xa\a)c2 c
[5]            (xxa\xa)(xxa\xb)(xc)
[6]        }
[7]        ⊃⍨∘(⍳∘(⌊/)⍨)∘(⊃∘⍴∘⊃¨)⍨⍵∘{⌽⍵⌽⌽c3 ⍵⌽⍺}¨⍳⍴⍵
[8]   ⍝ compare three lists
[9]   ⍝ ⍵ three lists presumed to be related
[10]  ⍝ ← three expansion lists to accomodate mis-matches
[11]  ⍝ Phil Last 2008-09-22 14:09
[12]   }
     ∇

     ∇ ca←{
[1]        q←''''∘{⍺,⍺,⍨⍵/⍨1+⍵=⍺}
[2]        if←{⍺⍺⍣(⍵⍵⊣⍵)⊢⍵}
[3]        v←⍎n←⍵
[4]        (⊂⍕n'←⍬'),(↓⍕(⊂n,',←'),q if(≡∘⍕⍨)¨v),⊂⍕n'⍴⍨←'(⍴v)
[5]   ⍝ create array -
[6]   ⍝ ⍵     fully-qualified name of array
[7]   ⍝ array mixed array (depth +/-2) of scalar numerics and text scalars or strings
[8]   ⍝ ←     executable expressions to reconstitute array
[9]    }
     ∇

     ∇ cb←{
[1]        {(⍵[0;⍵[1;]≠'|'])⍪1 0↓⍵}∘⊖⍣2 bx{
[2]            ⍵/⍨2∨/1,' '∨.≠⍵
[3]        }0 2↓⍕↓↑↑{⍵⊂⍨⍵='|'}¨↓⍪↑⍵
[4]   ⍝ column box
[5]    }
     ∇

     ∇ cc←cc
[1]    cc←819⌶
[2]   ⍝ convert case
[3]   ⍝ Phil Last 2017-12-18 10.03
     ∇

     ∇ cg←{
[1]        ⍺←# dx'⎕io ⎕ml'(⎕IO ⎕ML)
[2]        res←⍺
[3]        (0∊⍴txt←cu∘((⎕DR'')∘rf)⍣(~CR∊⍵),⍵):res
[4]        txt←txt re fl{('\',⍵)''}¨(CR,LF)CR LF
[5]        txt←{(+/∧\' '=⍵)⌽⍵}{⍵⌿⍨⍵∨.≠' '}⎕FMT txt~HT
[6]        txt←↓⊣⌿(∧\txt≠'=')⊖txt,[-0.1]cc txt
[7]        nms←(/⍨∘(∧\)∘(≠∘']'))⍨∘(1∘↓)¨txt/⍨msk←'['=⊃¨txt
[8]        txt←msk⊂txt
[9]        ~∨/msk←0≤⎕NC↑nms:res
[10]       nms txt/⍨←⊂msk
[11]       nss←res.{⍎⍵,'←⎕ns⍬'}¨nms
[12]       z←nss.{{q←'''"'
[13]               (≥/i j←+/∧\~(≠\⍵∊q)<[1]'=;'∘.=⍵):⍵     ⍝ unquoted ';' before '='
[14]               (0>⎕NC i↑⍵):⍵
[15]               (i↑⍵){⍺{⍎⍺,'←⍵'}{                      ⍝ key←value
[16]                       (>/1 0∊0⊃v f←⎕VFI ⍵):⍴∘f~∘1⍴f  ⍝ look like a duck?
[17]                       {⍵~q∩⊃⍵}⍵/⍨{(∨\⍵)∧⌽∨\⌽⍵}⍵≠' '  ⍝ trim and unquote
[18]                   }⍵
[19]               }(1+i)↓j↑⍵
[20]           }¨⍵}txt
[21]       0∊⍴cpy←nss/⍨2.1=nss.⎕NC⊂⊂'copysection':res     ⍝ requiring copies
[22]       cpy.copysection←cc cpy.(copysection~'#.[]')  ⍝ minuscule
[23]       0∊⍴cpy←cpy/⍨9.1=res.⎕NC cpy.copysection:res    ⍝ requiring extant copies
[24]       cpy←cpy ms∘res.⍎¨cpy.copysection               ⍝ merge
[25]       res
[26]  ⍝ config
[27]  ⍝ ⍵ ini file path\name
[28]  ⍝ ← namespace
[29]  ⍝     ini sections as subnss (with minuscule names)
[30]  ⍝       keys as vars            (ditto)
[31]  ⍝         values as text or numeric strings or scalars
[32]  ⍝ Phil Last ⍝ 2008-06-02 11:30
[33]   }
     ∇

     ∇ ch←{
[1]        9≠⎕NC ⍺:{⍵
[2]        }z,(#.⍎¯1↓z←⍺/⍨⌽∨\⌽⍺='.').⎕FX 1↓¨{⍵⊂⍨⍵=⊃⍵}re∘⍵⊃,/CR,¨⎕NR ⍺
[3]        ⊢z,(#.⍎¯1↓z←⍺/⍨⌽∨\⌽⍺='.').⎕FIX 1↓¨{⍵⊂⍨⍵=⊃⍵}re∘⍵⊃,/CR,¨⎕SRC⍎⍺
[4]   ⍝ change in defined operation
[5]   ⍝ ⍺ fully-qualified-fnname/opname/clsname
[6]   ⍝ ⍵ oldstring newstring
[7]   ⍝ ← result of in.situ.⎕FX on changed ⎕VR of function
[8]   ⍝ Phil Last ⍝ 2008-03-17 10:55
[9]    }
     ∇

     ∇ cl←{
[1]        ⍺←⌈/⍵
[2]        ⍵=⍺{⍵+⍺×⍺⍺≥⍺+⍵}as ⍵
[3]   ⍝ clump
[4]   ⍝ ⍺ desired maximum clump
[5]   ⍝ ⍵ sizes
[6]   ⍝ ← leading boolean partition mask such that
[7]   ⍝       ⎕ML←0 ⋄ (⍺ cl ⍵)⊂⍵
[8]   ⍝   or
[9]   ⍝       ⎕ML←3 ⋄ (+\⍺ cl ⍵)⊂⍵
[10]  ⍝   gives the largest contiguous collections of items of (⍵) having
[11]  ⍝   totals not greater than (⍺) excepting individual items of (⍵)
[12]  ⍝   that are greater than (⍺) dflt is maximum of (⍵)
[13]  ⍝ Phil Last ⍝ 2008-07-02 19:01
[14]   }
     ∇

     ∇ cm←{
[1]        ↑⍵⍴¨⍨↓1+⌽↑-1-⌽∘⍴¨⍵
[2]   ⍝ conform (mix)
[3]   ⍝ ⍵ any array
[4]   ⍝ ← mix a simple array
[5]   ⍝   mix a uniformly nested array
[6]   ⍝   otherwise uplift all items to the maximum rank and mix
[7]   ⍝   primitive in 14.0
[8]    }
     ∇

     ∇ cn←{
[1]        ⍵.{⍵⊣⍵.{⍎'(',⍺,')←⍵'}∘⍎⍨'⎕IO',,' ',⎕NL 2.1}#.⎕NS''
[2]   ⍝ clone
[3]   ⍝ ⍵ space
[4]   ⍝ ← unnamed space - having only & all of (⍵)'s vars.
[5]   ⍝   The reason for this fn is so the object can be passed into
[6]   ⍝   another function without fear that it might be changed.
[7]    }
     ∇

     ∇ co←{
[1]        ⊃⍵{(⊂⍵⍳⍺⍺)⌷(1+⍴⍵)↑⍺}/⍺
[2]   ⍝ corresponding
[3]   ⍝     A B co C ←→ A where B corresponds to C
[4]   ⍝ ⍺   A B
[5]   ⍝ A   vector
[6]   ⍝ B   vector conforming [0] with A
[7]   ⍝ ⍵   C
[8]   ⍝ C   array of members [1] of B
[9]   ⍝ ←   if A ←→ f¨ B then f¨ C
[10]  ⍝     (⊂B⍳C)⌷(1+⍴B)↑A
[11]  ⍝     shape of ⍵
[12]  ⍝ [0] A[⍴B] may be preferred alternative prototype
[13]  ⍝ [1] for C not in B return prototype of A but see [0]
[14]  ⍝ Phil Last 2016-10-27
[15]   }
     ∇

     ∇ cr←{
[1]        '(~<≤=≥>≠∨∧⍱⍲)\'
[2]   ⍝ default control chars for fi sc ps ec &c.
[3]    }
     ∇

     ∇ ct←{
[1]        q←''''∘{⍺,⍺,⍨⍵/⍨1+⍵=⍺}
[2]        if←{⍺⍺⍣(⍵⍵⊣⍵)⊢⍵}
[3]        (⍺,'←{')'⎕ml←0' 'r←⍬',(↓⍕(⊂'r,←⊂'),q if(≡∘⍕⍨)¨⍵),'↑r' ' }'
[4]   ⍝ create createTable function
[5]   ⍝ ⍺ name for function
[6]   ⍝ ⍵ mixed matrix of scalar numerics and text scalars or strings
[7]   ⍝ ← ⎕NR of function
[8]    }
     ∇

     ∇ ct0←{
[1]        q←''''∘{⍺,⍺,⍨⍵/⍨1+⍵=⍺}
[2]        if←{⍺⍺⍣(⍵⍵⊣⍵)⊢⍵}
[3]        v←⍎n←⍵
[4]        (⊂⍕n'←⍬'),(↓⍕(⊂n,',←'),q if(≡∘⍕⍨)¨v),⊂⍕n'⍴⍨←'(⍴v)
[5]   ⍝ create table -
[6]   ⍝ ⍵     fully-qualified name of array
[7]   ⍝ array mixed array (depth +/-2) of scalar numerics and text scalars or strings
[8]   ⍝ ← executable expressions to reconstitute array
[9]    }
     ∇

     ∇ cu←{
[1]        80≠⎕DR'':⍵    ⍝ non-unicode edition
[2]        {
[3]            ⍵↓⍨(⎕UCS⊃⍵)∊65534 65279
[4]        }⍵{
[5]            ∧/⍵<194:⍺ ⍝ maybe but doesn't matter
[6]            ∨/⍵>244:⍺ ⍝ can't be
[7]   ⍝ start not followed by continuation
[8]   ⍝         ∨/((⍵>193)∧⍵<245)>1↓((⍵>127)∧⍵<192),0:⍺
[9]   ⍝ continuation not preceded by start or continuation
[10]  ⍝         ∨/((⍵>127)∧⍵<192)>¯1↓1,(⍵>127)∧⍵<245:⍺
[11]           ⍝ let ⎕UCS test for start followed by wrong number of continuations
[12]           11::⍺
[13]           'UTF-8'⎕UCS ⍵
[14]       }⎕UCS ⍵
[15]  ⍝ convert UTF-8 or not
[16]  ⍝ ⍵ text string, - UTF-8 bytes or not
[17]  ⍝ ← clear text
[18]   }
     ∇

     ∇ cv←{⍺←⊢
[1]        ↑⍎'↓⍺ sc' '(∩∪)'ps ⍵
[2]   ⍝ intersect or union (Ctrl+c Ctrl+v)
[3]    }
     ∇

     ∇ cw←{
[1]        {1↓⍵⊣⎕FUNTIE 1↑⍵}⊃{⍵,⍺ ⎕FAPPEND 1↑⍵}/(⌽,⍺),{
[2]            22::⍵ ⎕FCREATE 0
[3]            ⍵ ⎕FSTIE 0
[4]        }⍵
[5]   ⍝ component write
[6]   ⍝ ⍺ vector of arrays to write
[7]   ⍝ ⍵ file path/name - create if missing
[8]   ⍝ ← component numbers written
[9]   ⍝ Phil Last ⍝ 2008-07-04 14:55
[10]   }
     ∇

     ∇ da←{⍺←⊢
[1]        f←{⍺⍺⍣(2<≢⍴⍵)⊢⍵}
[2]        ∇ f⊂⍤2 f ⍵
[3]   
[4]        ∇⍣(2<≢⍴z)⊢z←⊂⍤2⍣(2<≢⍴⍵)⊢⍵
[5]   ⍝
[6]    }
     ∇

     ∇ dc←{
[1]        ⍴∘⍵~∘1⍴⍵
[2]   ⍝ decay
[3]   ⍝ ⍵ array
[4]   ⍝ ← (⍵) with all ones removed from its shape
[5]   ⍝   1 row or 1 col matrix becomes vector
[6]   ⍝   singleton become scalar
[7]   ⍝ Phil Last ⍝ 2008-07-18 10:06
[8]    }
     ∇

     ∇ df←{
[1]        ⍵{(⍺.⎕DF ⍵)⊢⍕⍺}⍵.⎕DF ⎕NULL
[2]   ⍝ format ref - sans ⎕DF
[3]   ⍝ ⍵ ns-ref
[4]   ⍝ ← format of ns-ref - full path name
[5]   ⍝   ignoring ⎕DF by using it twice!
[6]   ⍝ Phil Last ⍝ 2008-03-13 23:14
[7]    }
     ∇

     ∇ di←{⍺←⊢ ⋄ p←⍺⊣0
[1]        ⎕PP←{0::⍵ ⋄ ∇ ⎕PP←1+⍵}⎕PP
[2]        (⍴⍵){
[3]            1<|≡⍵:⍺ ∇{⍵/⍨' '∨.≠⍵}⎕FMT(⍴∇⊢)¨⍵⍴⍨1⌈⍴⍵
[4]            (⊃'~''#'/⍨(⍬''∊⊂0⍴⍵),1){
[5]                ⍉↑⍺{(⊂⌽⍺,1↓⌽⊃⍵),1↓⍵}↓⍉⍵
[6]            }(⎕D,⎕A,'abcdefghijklmnopqrstuvwxyz','*')[62⌊↑,↓⍺]{ ⍝ use '*' for larger than 61
[7]                (⍴⍵)⍴(' '≠⍺↑⍨⍴⍵)⊖↑⍵ ⍺}⍺{⍵/⍨1⌈1+(0⊥⍴⍵)↑-2-⍴⍺
[8]            }p bx ⎕FMT ⍵⍴⍨1⌈⍴⍵
[9]        }⍵
[10]  ⍝ display
[11]  ⍝ ⍺ internal
[12]  ⍝ ⍵ any array
[13]  ⍝ ← display form
[14]  ⍝ Phil Last ⍝ 2008-01-23 13:35
[15]  ⍝ {{⊂[¯2↑⍳⍴⍴⍵]⍵}⍣(⌊0.5×⍬⍴⍴⍴⍵)⊢⍵}
[16]  ⍝ Phil Last 2017-07-01 09.06
[17]   }
     ∇

     ∇ dn←{
[1]        (nam num exp)←1↓¨{⍵⊂⍨{⍵∧4>+\⍵}⍵∊'[]'}'[',⍵
[2]        scr←9=⎕NC nam
[3]        new←(⊂exp)((⍎num)mg)(scr=1 0)⎕SRC∘⍎or ⎕NR nam
[4]        (spc nam)←'.'pn nam
[5]        1:⊢(⍎spc,scr⊃'⎕fx' '⎕fix')new
[6]   ⍝ define
[7]   ⍝ ⍵ string - "#.path.itemname[n] expression"
[8]   ⍝   itemname may be a function, operator, class or scripted space
[9]   ⍝ ← result of #.path.⎕FX or #.path.⎕FIX on amended ⎕NR or script of named item
[10]   }
     ∇

     ∇ dr←{
[1]        ⍺←⌊0.5++/⍵
[2]        n+(×e)×(⍳⍴⍵)∊(|e←⍺-+/n←⌊0.5+⍵×⍺÷+/⍵)⍴⍒|⍵
[3]   ⍝ [re]distributive rounding
[4]   ⍝ [⍺]   [new] integer sum
[5]   ⍝  ⍵    vector
[6]   ⍝  ←    ⍵ rounded and scaled to sum to ⍺
[7]   ⍝       total rounding error distributed
[8]   ⍝       among items of greatest magnitude
[9]   ⍝ 2007-12-04 10.25 comp.lang.apl cb75f8564a3e0b22
[10]  ⍝ http://groups.google.com/group/comp.lang.apl/browse_thread/thread/cb75f8564a3e0b22
[11]   }
     ∇

     ∇ ds←{ ⍝ see (es)
[1]        ⊃⍣(1=≢⍵)⊢⍵
[2]   ⍝ disclose single
[3]   ⍝ ⍵ any array
[4]   ⍝ ← ⍵ or ⊃⍵ if single ⍵
[5]   ⍝ Phil Last ⍝ 2008-03-06 09:28
[6]    }
     ∇

     ∇ dt←{
[1]        ⍺⊣(,⍺)∘.{⍺.((⊃⍬⍴⍵){⍴⍎⍺,'←⍵'/⍨0=⎕NC ⍺}{⊃⍬⍴⍵}⍣(2∊⍴⍵)⊢1↓⍵)},⊂⍣(1=≡⊃⍵)⊢⍵
[2]   ⍝ above is existing code running in V12.0.5
[3]   ⍝ below is equivalent using ⍺{...}¨¨⊂⍵ instead of ⍺∘.{...}⍵.
[4]        ⍺⊣(,⍺){⍺.((⊃⍬⍴⍵){⍴⍎⍺,'←⍵'/⍨0=⎕NC ⍺}{⊃⍬⍴⍵}⍣(2∊⍴⍵)⊢1↓⍵)}¨¨⊂,⊂⍣(1=≡⊃⍵)⊢⍵
[5]   ⍝ default
[6]   ⍝ ⍺ ns(s)
[7]   ⍝ ⍵ name-value pairs
[8]   ⍝ ← ns(s) with named vars having values where previously missing
[9]   ⍝   NB result IS ⍺ with named vars as stated.
[10]  ⍝      In other words the argument is changed!!!!
[11]  ⍝ Phil Last ⍝ 2006-02-21 20:54
[12]   }
     ∇

     ∇ dx←{
[1]        ⍺←⎕THIS
[2]        ⍺.(⎕NS''){⍺⍺⊣⍺⍺.⍎⍕'(',⍺,')←⍵'}/ds\⍵
[3]   ⍝ dictionary
[4]   ⍝ ⍺   space - dflt here
[5]   ⍝ ⍵   names values
[6]   ⍝ ←   ns within space ⍺ wherein vars named (names) valued (values)
[7]   ⍝ Phil Last ⍝ 2008-03-06 18:58
[8]    }
     ∇

     ∇ dy←{⍺←⊢
[1]        1≡⍺ 1:{⍵⊣⍵.(n v)←⊂,0}⎕NS''
[2]        cat←⍺
[3]        name←⊃nv←⊂if≡⍵
[4]        new←0≡cat.{((⍴n)|n⍳⍵)⊃n}⊂name    ⍝ missing
[5]        new:1⊃cat.(n v),←⊂¨nv            ⍝ add
[6]        value←cat.{(n⍳⍵)⊃v}⊂name         ⍝ retrieve
[7]        value⊣cat.(n v)/⍨←⊂~cat.n∊⊂name  ⍝ remove
[8]   ⍝ maintain dictionary of names values "n" "v" with initial value ,0
[9]   ⍝ monad:
[10]  ⍝ ⍵ ?
[11]  ⍝ ← empty store
[12]  ⍝ dyad:
[13]  ⍝ ⍺ store
[14]  ⍝ ⍵ name value
[15]  ⍝ ← if name not in store
[16]  ⍝   value
[17]  ⍝   if name already in store
[18]  ⍝   value - and name is removed
[19]  ⍝ Phil Last 2015-05-07
[20]   }
     ∇

     ∇ ec←{
[1]        ⍺←cr'' ⋄ e←'\'
[2]        ⍵(⍺{⍵∘/¨⍺{⍺ ⍵}(⍺∊⍺⍺)∧¯1⌽⍵})~(⍵=e)∧(¯1⌽⍵≠e)∧(1⌽⍵∊⍺,e)
[3]   ⍝ escape
[4]   ⍝ ⍺ control chars
[5]   ⍝ ⍵ string
[6]   ⍝ ← (amended string)(control flags)
[7]   ⍝ where:
[8]   ⍝   amended string has actioned escape chars '\' removed
[9]   ⍝   control flags is boolean length of amended string
[10]  ⍝       with 1 where amended string is unescaped control
[11]  ⍝ Phil Last ⍝ 2009-02-06 08:51
[12]   }
     ∇

     ∇ ed←{
[1]        ({⍵⊣⍵.s←''}⎕NS''){
[2]            ⍺.(''⊣(⎕NS'').(⎕ED&'_'⊣_←⍵)) ⍝ ⍕⍪⍣(1 2≡(⍴∘⍴,≡)⍵)⊢⍵))
[3]        }{
[4]            9.1≢⎕NC⊂,'⍵':# ⍺⍺ ⍵
[5]            ⍵∊⍺.s:''
[6]            ⍺.s,←⍵
[7]            n←∇∘⍵.⍎/⍺,⍪~∘' '¨↓⍵.⎕NL 9.1
[8]            ⍵ ⍺⍺↑({⊢/('['∊¨⍵)⌽(⊂'##'),⍪⍵}⍕¨⍵),¨↓'.',⍵.⎕NL 2 3 4
[9]        }⍵
[10]  
[11]       {(⎕NS'').(⎕ED&'_'⊣_←⍵)} ⍝ is sufficient for an array
[12]  ⍝ show
[13]  ⍝ ⍺  ignored
[14]  ⍝ ⍵  array or space
[15]  ⍝ ←  null
[16]  ⍝    display array in editor
[17]  ⍝ or display member list of space and
[18]  ⍝    recursively for contained member spaces
[19]  ⍝ Phil Last ⍝ 2008-03-12 08:32
[20]  ⍝ Phil Last 2015-10-19
[21]   }
     ∇

     ∇ en←{
[1]        ((1+⌊⍺⍟1⌈⌈/|⍵)⍴⍺)⊤⍵
[2]   ⍝ encode
[3]   ⍝ ⍺ base
[4]   ⍝ ⍵ numeric
[5]   ⍝ ← ⍵ encoded to base ⍺ with sufficient digits
[6]   ⍝ 2 1/2 times quicker than ⊥⍣¯1
[7]   ⍝ Phil Last ⍝ 2008-03-11 18:10
[8]    }
     ∇

     ∇ es←{ ⍝ see (ds)
[1]        ⊂⍣(1=≡⍵)⊢⍵
[2]   ⍝ enclose simple
[3]   ⍝ ⍵ any array
[4]   ⍝ ← ⍵ or ⊂⍵ if simple ⍵
[5]   ⍝ Phil Last ⍝ 2008-03-06 09:27
[6]    }
     ∇

     ∇ ev←{0::⎕SIGNAL/⌽⎕EN,⎕DM
[1]        ##.AN.decode ⍵
[2]   ⍝ APLAN decode ⍵
[3]    }
     ∇

     ∇ ex←{
[1]        ⍵[⌈\(⍳⍴⍵)×~∊∘∊⍨⍵]
[2]   ⍝ extend list
[3]   ⍝ ⍵ list extend
[4]   ⍝ ← same list with nulls replaced by most recent non-null
[5]   ⍝   nulls deemed to be empty or all ' ' and/or 0
[6]   ⍝   so '' ⍬ ' ' 0 (' '0'')(⍳2 0 3) is null as are all its parts
[7]   ⍝ Phil Last ⍝ 2008-04-23 17:28
[8]    }
     ∇

     ∇ fc←{⍺←⊢
[1]        {1↓¨⍵/⍨∧\'⍝'=⊣/¨⍵}(1+1⊃⎕LC)↓⎕NR 1⊃⎕XSI
[2]   ⍝ following (full-line) comments in caller
[3]   ⍝ Phil Last 2015-02-24
[4]    }
     ∇

     ∇ fgh←{⍺←⊢
[1]        #.(f←{⍺←⊢ ⋄ '(',⍺,' f ',⍵,')'})
[2]        #.(g←{⍺←⊢ ⋄ '(',⍺,' g ',⍵,')'})
[3]        #.(h←{⍺←⊢ ⋄ '(',⍺,' h ',⍵,')'})
[4]   ⍝
[5]    }
     ∇

     ∇ fi←{⍝ find
[1]        ⎕ML←0
[2]        ⍺←#
[3]        0::((⊃⎕DM),' - Try escaping "',(⍵∩'(~<≤=≥>≠∨∧⍱⍲)\'),'"')⎕SIGNAL ⎕EN
[4]        ('1∊⍵⍷⍨'ps ⍵){⍵/⍨⍺∘{⍺{⍎⍺}⍕⍵{
[5]                    (⍵∊3 4):2↓⊃,/' ',CR,¨⎕NR ⍺
[6]                    (⍵=2):⍎⍺
[7]                    (⍵=9):{0::'' ⋄ ⎕SRC⍎⍵}⍺
[8]                    ''
[9]                }⎕NC ⍵}¨⍵}{
[10]           2=≡⍵:⍵
[11]           (⍬≡0⍴⍵):li ⍵
[12]           (9=⎕NC'⍵'):⍵ li 3.1 3.2 4.1 4.2 9.4
[13]           (⊃{⍺,'∨',⍵}/⊂if≡⍵)lf # li 3.1 3.2 4.1 4.2 9.4
[14]           (''≢0⍴⍵):⍵ li 3.1 3.2 4.1 4.2 9.4
[15]           ⍵ lf # li 3.1 3.2 4.1 4.2 9.4
[16]       }⍺
[17]  ⍝ find
[18]  ⍝ ⍺ ref     - search all in or below
[19]  ⍝   string  - logical wildcard selection of candidates anywhere
[20]  ⍝   numbers - candidate ⎕NCs - dflt - 3.1 3.2 4.1 4.2 9.4
[21]  ⍝ ⍵ search string - can contain executables "(~<≤=≥>≠∨∧⍱⍲)". see ps
[22]  ⍝ ← fully qualified names of arrays, fns, ops & classes where found.
[23]  ⍝ Phil Last ⍝ 2008-03-04 13:53
[24]   }
     ∇

     ∇ fm←{⍺←⊢
[1]        0::⎕SIGNAL/⌽⎕EN,⎕DM
[2]        ⍺ ##.AN.format ⍵
[3]   ⍝ APLAN format ⍵
[4]    }
     ∇

     ∇ fo←{
[1]   ⍝     #.{
[2]        {FO}'FO'⎕WC⊢FO←'OLECLIENT' 'Scripting.FileSystemObject'
[3]   ⍝     }0
[4]   ⍝ file system object
[5]   ⍝ ⍵ ?
[6]   ⍝ ← file system object
[7]    }
     ∇

     ∇ fq←{⍺←⊢
[1]        (⍺⊣0){⍵[;⍋⍺×⊢⌿⍵]}⍵{⍵,[-0.1]¯2-/((⌷⍨∘⊂∘⍋⍨⍵⍳⍺)⍳⍳⍴⍵),⍴⍺}∪⍵
[2]   ⍝ frequency
[3]   ⍝ [⍺] order ¯1|0|1 - dflt=0 - ¯1=descending; 0=first occurrence; 1=ascending
[4]   ⍝ ⍵ list
[5]   ⍝ ← 2d 2 rows - (unique ⍵)⍪(frequency)
[6]   ⍝ Phil Last ⍝ 2008-03-05 11:37
[7]    }
     ∇

     ∇ fr←{⍺←⊢
[1]        (⊃⊢∘⊂/(≡⍵)↓0 0 ⍵){⊃1↓0,⍵⌿⍨{(⍵≠0)∧⍵=⌈/⍵}+/∨\('.',⍺,' ')⍷⍕⍪⍵}¨⊂nt ⍺⊣#
[2]   ⍝ find ref(s) in tree of tgt
[3]   ⍝ ⍺ tgt - space - dflt #
[4]   ⍝ ⍵ simple name(s)
[5]   ⍝ ← scalar or vector ref(s) nearest root or zero(s)
[6]   
[7]   ⍝ was:
[8]   ⍝     ⊃⍺⍺/⍺,⊂⍵
[9]   ⍝ for loop (fold right)
[10]  ⍝ a b c d f fr w ←→ a f(b f(c f(d f w)))
[11]  ⍝ Phil Last ⍝ 2011-10-20 07:26
[12]   }
     ∇

     ∇ ft←{
[1]        ⍵{(0,⍴,⍺)↓⍵⌿⍨>/⍺⍷⍵}{⍵⌽⍨+/∧\' '=⍵}⎕CR⊃1↓⎕XSI
[2]   ⍝ Financial Times - "No Financial Times? No Comment!"
[3]   ⍝ ⍵ string
[4]   ⍝ ← lines of calling function starting in that string
[5]   ⍝   presumed to start with a '⍝' but don't need to.
[6]   ⍝ Phil Last ⍝ 2008-04-30 17:18
[7]    }
     ∇

     ∇ gc←{
[1]        ⍺←#
[2]        w←⍵
[3]        (s r)←⍵
[4]        c←{⊃⍵<∨/⍵}('\',cr'')∊s
[5]        s←{⍵ re fl{⍵,∘⊂¨'\',¨⍵}~∘'\'cr''}if c,s
[6]        (0∊⍴z←{⍵/⍨(⎕NC ⍵)∊3.1 3.2 4.1 4.2 9.4}⍺ fi s):z
[7]        z⊣z ch¨⊂(⊃ec s)r
[8]   ⍝ global change
[9]   ⍝ ⍺ space - dflt #
[10]  ⍝ ⍵ old new strings
[11]  ⍝ ← nms changed
[12]  ⍝ Phil Last ⍝ 2008-03-17 16:51
[13]   }
     ∇

     ∇ gd←{⍺←⊢
[1]        z←⎕FMT'-'⍪'|',(⍺⊣0){
[2]            ⍺:⍉↑,/{⍵'-'}¨⍉⍵
[3]            '-'⍪⍨⍵
[4]        }↑,/{⍵'|'}¨⍵
[5]        r←(∨/z='-')∧∧/z∊'|- '
[6]        c←(∨⌿z='|')∧∧⌿z∊'|- '
[7]        (r⌿z)←'-'
[8]        (c/z)←'|'
[9]        ((,r∘.∧c)/,z)←'+'
[10]       z
[11]  ⍝ grid
[12]  ⍝ ⍺ 0 sep cols not rows
[13]  ⍝   1 sep cols and rows
[14]  ⍝ ⍵ array
[15]  ⍝ ← boxed
[16]   }
     ∇

     ∇ gw←{
[1]        (⎕NS''){0::⍺ ⋄ ⍺⊣⍺.⎕CY ⍵}⍵
[2]   ⍝ get ws
[3]   ⍝ ⍵ name of accessible ws
[4]   ⍝ ← anon root ns containing root and ns-tree of ws named ⍵
[5]    }
     ∇

     ∇ ht←{
[1]        (⊃⍵)(1↓⍵)
[2]   ⍝ ⍵ list
[3]   ⍝ ← head and tail
[4]   ⍝ Phil Last ⍝ 2009-01-12 11:30
[5]    }
     ∇

     ∇ hx←{
[1]        t←0∊⊃⍬⍴0⍴⊂⍵
[2]        a←⎕D,'abcdef',⎕D,6⍴⎕A
[3]        t:⍉a⌷⍨⊂16⊥⍣¯1⊢⍉⍵
[4]        ⍉16⊥16|a⍳⍉⍵
[5]   ⍝ ⍵ simple dec- or hex-array
[6]   ⍝ ← simple hex- or dec-array
[7]   ⍝   accepts hex as CAPS or small
[8]   ⍝   returns hex as small
[9]   ⍝   dec to hex increases rank at right
[10]  ⍝   hex to dec decreases rank from right
[11]   }
     ∇

     ∇ ia←{⍺←⊢
[1]        ~∘' '¨(⊢(⌿⍨)0≤⎕NC)⎕NR⊃⎕SI
[2]        alpha
[3]        bravo
[4]        charlie
[5]        delta
[6]        echo
[7]        foxtrot
[8]        golf
[9]        hotel
[10]       india
[11]       juliet
[12]       kilo
[13]       lima
[14]       mike
[15]       november
[16]       oscar
[17]       papa
[18]       quebec
[19]       romeo
[20]       sierra
[21]       tango
[22]       uniform
[23]       victor
[24]       whisky
[25]       x_ray
[26]       yankee
[27]       zulu
[28]  ⍝ ICAO (international civil aviation organization) alphabet
[29]   }
     ∇

     ∇ ic←{
[1]        m←0
[2]        ⍺←m←1
[3]        f←¯1∘tc
[4]        m:f ⍵
[5]        ≡/f¨⍺ ⍵
[6]   ⍝ ignore case
[7]   ⍝ ⍺ [string]
[8]   ⍝ ⍵ string
[9]   ⍝ ← strings match ignoring case & non-alphanumerics
[10]  ⍝   or only string lower case and non-alphanumeric
[11]  ⍝ also:
[12]  ⍝ interesting characters:
[13]  ⍝   181: mu (micro- prefix) (greek letter)
[14]  ⍝  8704: for all (upside down A)
[15]  ⍝  8707: there exists (backwards E)
[16]   }
     ∇

     ∇ is←{0::⎕NS⍣(≢⍴⍵)⊢''
[1]        ≢⍴⍵:r⊣⍎⍕'r.('n')←v'⊣r←⎕NS''⊣v←↓⍉↑⍵.(⍎¨)n←(⊢⍴⍨2⌈≢)¨∩/⍵.⎕NL-2
[2]        ≢⊢⍵:r⊣⍎⍕'r.('n')←v'⊣r←{⎕NS''}¨⍳≢v←↓⍉↑⍵.⍎¨n←(⊢⍴⍨2⌈≢)↓⍵.⎕NL 2
[3]   
[4]   ⍝ invert space(s)
[5]   ⍝ ⍵ space or list thereof
[6]   ⍝ ⍵ space with named lists
[7]   ⍝ ← list of spaces with named items
[8]   ⍝   after lists overtaken to longest
[9]   ⍝ or
[10]  ⍝ ⍵ list of spaces with named items
[11]  ⍝ ← space with named lists
[12]  ⍝   of intersect of named items
[13]  ⍝ After normalisation is is self inverse.
[14]  ⍝    [
[15]  ⍝       nam←('five' 'zero' 'two')
[16]  ⍝       num←(5 0 2)
[17]  ⍝    ]
[18]  ⍝ vs
[19]  ⍝    [
[20]  ⍝       nam←'five'
[21]  ⍝       num←5
[22]  ⍝    ][
[23]  ⍝       nam←'zero'
[24]  ⍝       num←0
[25]  ⍝    ][
[26]  ⍝       nam←'two'
[27]  ⍝       num←2
[28]  ⍝    ]
[29]  ⍝ Phil Last 2017-04-10 10.14
[30]   }
     ∇

     ∇ js←{⍺←⊢
[1]        head←':namespace ',name←⍺⊣'.'nn df ⍵
[2]        par←'⍝ ## ←→ ',,df ⍵.##
[3]        consts←'(⎕IO ⎕ML)←',⍕⍵.(⎕IO ⎕ML)
[4]        fns←,⊃,/(⊂''),⍵.((⊂'')∘,∘⎕NR¨↓⎕NL 3.2 4.2)
[5]        fns,←⊃,/(⊂''),⍵.({('∇',¨1⍴⍵),1↓⍵,'∇'}∘⎕NR¨↓⎕NL 3.1 4.1)
[6]        tail←':endnamespace ⍝ ',name
[7]        head par''consts,fns,''tail
[8]   ⍝ flat script from defined fns and ops only
[9]    }
     ∇

     ∇ ki←{
[1]        1:2↓¯2↓⎕NR⊃⎕SI ⍝ not this
[2]        +/∧\
[3]        +/∧\' '=
[4]        ,/
[5]        ,←
[6]        /⍳
[7]        /⍳⍴
[8]        0=⍴
[9]        0=⍴⍴
[10]       0∊⍴
[11]       1=≡
[12]       {(+/∧\' '=⍵)↓⍵}
[13]       {(+/∨\' '≠⌽⍵)↑¨↓⍵}
[14]       {(↓⍺)⍳↓⍵}
[15]       {(∨\' '≠⍵)/⍵}
[16]       {0}
[17]       {}
[18]       {⍵[⍋⍵]}
[19]       {⍵[⍋⍵;]}
[20]       {⍵}
[21]       {⍺ ⍵}
[22]       {⍺}
[23]       ~∘' '¨↓
[24]       ↓⍉↑
[25]       ∧\' '=
[26]       ⊃∘⍴¨
[27]       ⊃⌽
[28]       ⍴⍴
[29]  ⍝ known idioms
[30]   }
     ∇

     ∇ kl←{⍺←⊢
[1]        y m←0 100⊤⍵
[2]        y←y+(y=0)⊃0,⎕TS
[3]        y<100:∇¨(⍵×100)+1+4 3⍴⍳12
[4]        l←>/0=4 100 400|y
[5]        md←0 31 28,10⍴5⍴31 30
[6]        fy←{(⍵×365)+(⌊⍵÷4)-(⌊⍵÷100)-⌊⍵÷400}y-1
[7]        ytd←(m⊃+\0,md)+l∧m>2
[8]        r←1↓43↑' ',1+⍳(m⊃md)+l∧m=2
[9]        t←~∘' ',m⊃' ',{⍵/⍨¯1≠⎕NC ⍵}⎕NR⊃⎕SI
[10]       1:↑(⊂⍕t,y),↓⍕'SMTWTFS'⍪6 7⍴(-7|1+fy+ytd)⌽r
[11]       January
[12]       February
[13]       March
[14]       April
[15]       May
[16]       June
[17]       July
[18]       August
[19]       Sepember
[20]       October
[21]       November
[22]       December
[23]  ⍝ kalends
[24]   }
     ∇

     ∇ ku←{⍺←⊢
[1]        ~∨/b←⍺=⊢/¨w←⍵:w
[2]        (b/w)←b/2{(¯1↓⍺),⍵}/w,' '
[3]        ⍺ ∇(¯1↓1,~b)/w
[4]   ⍝ KontinUe - expects {(+/∨\' '≠⌽⍵)↑¨↓⍵} matrix
[5]    }
     ∇

     ∇ la←{
[1]        {⍵{(⍺,⍵)[⍒⍵;]}2 ⎕AT ⍵}⍵ li 3.1 3.2 4.1 4.2
[2]   ⍝ latest fns/ops in ns ⍵
[3]   ⍝ Phil Last ⍝ 2008-01-17 12:11
[4]    }
     ∇

     ∇ lc←{
[1]        0 ll ⍵
[2]   ⍝ lower case clone
[3]   ⍝ ⍵ space with vars
[4]   ⍝ ← space as ⍵ but all vars are lower case
[5]    }
     ∇

     ∇ lf←{
[1]        ⍵⌿⍨⍺ lw ⍵
[2]   ⍝ ⍺ logical filter - wildcards '(*this∨that*)∧~the*other'
[3]   ⍝ ⍵ namelist - 2d or string list
[4]   ⍝ ← names in (⍵) matching filter
[5]   ⍝ Phil Last ⍝ 2008-06-11 21:14
[6]    }
     ∇

     ∇ li←{⍺←#
[1]        1↓⊃,/' ',⍵∘{(⍕⍵)∘,¨~∘' '¨↓'.',⍵.⎕NL|⍺}¨nt ⍺
[2]   ⍝ list
[3]   ⍝ ⍺ space
[4]   ⍝ ⍵ nameclasses ∊ 0.1×⍳100
[5]   ⍝ ← fullname list all nameclass items in or below space
[6]   ⍝ Phil Last ⍝ 2008-01-09 12:09
[7]    }
     ∇

     ∇ li0←{
[1]        ⎕ML←0
[2]        ⍺←#
[3]        1↓⊃,/' ',⍵∘{(⍕⍵)∘,¨~∘' '¨↓'.',⍵.⎕NL|⍺}¨nt ⍺
[4]   ⍝ list
[5]   ⍝ ⍺ space
[6]   ⍝ ⍵ nameclasses ∊ 0.1×⍳100
[7]   ⍝ ← fullname list all nameclass items in or below space
[8]   ⍝ Phil Last ⍝ 2008-01-09 12:09
[9]    }
     ∇

     ∇ ll←{
[1]        ⍺{s←⎕NS'' ⋄ s⊣s.⍎(⍺⍺ cc ⍺),'←⍵'}/⍵.({⍵(⍎⍵)}'⎕io',,' ',⎕NL 2.1)
[2]   ⍝ case-folded clone
[3]   ⍝ ⍵ space with vars
[4]   ⍝ ← space as ⍵ but all vars are lower/upper case according ⍺
[5]    }
     ∇

     ∇ ls←{0∊⍴⍵:''
[1]        ⍺←'&'
[2]        s←1↓⌽(1,⍴⍵)/(' ',⍺,' ')', '
[3]        (1+⍴0⊃s)↓⊃,/' ',s,¨⍵
[4]   ⍝ list
[5]   ⍝ ⍺ alternative to '&'
[6]   ⍝ ⍵ list
[7]   ⍝ ← string
[8]   ⍝   ls 'one' 'two' 'three' 'four'
[9]   ⍝ one, two, three & four
[10]   }
     ∇

     ∇ lv←{
[1]        1:⎕CR⊃⎕SI
[2]   ⍝ logical vector reduction
[3]   ⍝ In the following list of logical vector reductions the
[4]   ⍝ comment describes ⍵ when 1<⍴⍵ and the result is true.
[5]   ⍝ The boolean digits are the values, for each ⍺⍺/ of ∘.⍺⍺⍨0 1
[6]   ⍝ The two D:fns and two dervs are the missing logicals - (0 a c f)
[7]   
[8]        0 0 0 0 ⋄ {0}/⍵  ⍝ never
[9]        0 0 0 1 ⋄ ∧/⍵    ⍝ no zeros
[10]       0 0 1 0 ⋄ >/⍵    ⍝ odd leading ones
[11]       0 0 1 1 ⋄ ⊣/⍵    ⍝ a leading one
[12]       0 1 0 0 ⋄ </⍵    ⍝ last is only one
[13]       0 1 0 1 ⋄ ⊢/⍵    ⍝ last is one
[14]       0 1 1 0 ⋄ ≠/⍵    ⍝ odd ones
[15]       0 1 1 1 ⋄ ∨/⍵    ⍝ at least one one
[16]       1 0 0 0 ⋄ ⍱/⍵    ⍝ odd leading zeros else last is only one
[17]       1 0 0 1 ⋄ =/⍵    ⍝ even zeros
[18]       1 0 1 0 ⋄ (~⊢)/⍵ ⍝ last is parity of width
[19]       1 0 1 1 ⋄ ≥/⍵    ⍝ even leading zeros
[20]       1 1 0 0 ⋄ (~⊣)/⍵ ⍝ a leading zero
[21]       1 1 0 1 ⋄ ≤/⍵    ⍝ last is not only zero
[22]       1 1 1 0 ⋄ ⍲/⍵    ⍝ even leading ones else last is only zero
[23]       1 1 1 1 ⋄ {1}/⍵  ⍝ always
[24]   }
     ∇

     ∇ lw←{
[1]        (⍺≡∊⍺):(⍬⍴⍴⍵)⍴0
[2]        ⍺{⍎'⍵ wi'ps ⍺}↑⍵
[3]   ⍝ ⍺ logical wildcard - wildcards '(*this∨that*)∧~the*other'
[4]   ⍝ ⍵ namelist - 2d or string list
[5]   ⍝ ← boolean - which names in (⍵) match filter
[6]    }
     ∇

     ∇ md←{
[1]        ⍬⍴⍵{⍵/⍨=∘(⌈/)⍨¯2-/((⌷⍨∘⊂∘⍋⍨⍵⍳⍺)⍳⍳⍴⍵),⍴⍺}∪⍵
[2]   ⍝ mode
[3]   ⍝ ⍵ list
[4]   ⍝ ← most frequent item or first occurring of multiple
[5]    }
     ∇

     ∇ ml←{
[1]        r←re fl∘('&' '&amp;')('<' '&lt;')('>' '&gt;')
[2]        c←r if{'<'≠⍬⍴⍵}
[3]        ((1=≡⍺)⊃⍺(⊂⍺)){
[4]   ⍝     (⊃{⊂⍵}/(1∩≡⍺),⊂⍺){
[5]            1⌽'><',(⊃{⍵,⊃{' ',⍺,1⌽'"="',r ⍵}∘⍕/⍺}/⌽⍺),⊃(×⍴⍵)↓'/'('>',(c ⍵),'</',⊃⍺)
[6]        },⍕⍵
[7]    }
     ∇

     ∇ mn←{
[1]        ⍺←''
[2]   ⍝    mu below is ⎕ucs 181
[3]        m n←'yzafpnµm' 'kMGTPEZY'
[4]        (⊂⍺),¨⍨⍵{(m,(⊂''),n)[⍵+8],¨⍨⍕¨3 sg ⍺÷1000*⍵}⌊1000⍟|⍵+⍵=0
[5]   ⍝ magnitute
[6]   ⍝ ⍺ unit
[7]   ⍝ ⍵ simple number array
[8]   ⍝ ← (⍵) scaled such that (1 ≤ |n) ∧ 1000 > |n
[9]   ⍝   followed by the relevant SI Prefixes and the unit (⍺)
[10]  ⍝ 'g' ∇ 12345 0.12345 → 12.345kg  123.45mg
[11]  ⍝ yocto, zepto, atto, femto, pico, nano, micro, milli,
[12]  ⍝ 1e¯24  1e¯21  1e¯18 1e¯15  1e¯12 1e¯9  1e¯6   1e¯3
[13]  ⍝ kilo,  Mega,  Giga, Tera,  Peta, Exa,  Zetta, Yotta.
[14]  ⍝ 1e3    1e6    1e9   1e12   1e15  1e18  1e21   1e24
[15]   }
     ∇

     ∇ ms←{
[1]        ⍺⊣⍎{'⍺.(',⍵,')←⍵.(',⍵,')'}'⎕io',⍕⊃~/(⍵ ⍺).⎕NL-2
[2]   ⍝ merge spaces
[3]   ⍝ ⍺ space
[4]   ⍝ ⍵ space
[5]   ⍝ ← (⍺) with union of vars in (⍺) & (⍵)
[6]   ⍝   vars already in (⍺) ARE NOT OVERWRITTEN
[7]   ⍝   unlike 'a'⎕ns b which overwrites common vars in a with values from b
[8]   ⍝ in ms/A B C
[9]   ⍝ C will remain unchanged
[10]  ⍝ B will keep its own and gain vars from C not in B
[11]  ⍝ A will keep its own and gain vars from B ms C not in A
[12]  ⍝ no values are changed.
[13]  ⍝ Phil Last ⍝ 2008-09-02 22:05
[14]   }
     ∇

     ∇ mv←{
[1]        x n←((⌈/⍺)⌈⌈/⍵),(⌊/⍺)⌊⌊/⍵
[2]        (⍵[⍋⍵],x)[(0,+\(⍳1+x-n)∊⍵-n)[⍺-n]]
[3]   ⍝ move
[4]   ⍝ ⍺ integer vector
[5]   ⍝ ⍵ integer vector
[6]   ⍝ ← ⍺ with items not in ⍵ moved to next ⍵
[7]   ⍝   {(⍵,⌈/⍺)[+/⍺∘.>⍵]}∘{⍵[⍋⍵]} can be
[8]   ⍝   quicker for relatively small ⍵
[9]    }
     ∇

     ∇ mx←{
[1]        ↑⍵⍴¨⍨↓1+⌽↑-1-⌽∘⍴¨⍵
[2]   ⍝ mix variable rank
[3]    }
     ∇

     ∇ na←{
[1]        ⎕ML←0
[2]        ⍺←#(2 3 4)
[3]        s c←⍺
[4]        c←(s≡c)⊃c(2 3 4)
[5]        (,∘(⍵∘,)⍨'*'~⍵)lf s li c
[6]   ⍝ names
[7]   ⍝ ⍺ space [ nameclasses ]
[8]   ⍝ ⍵ wildcard
[9]   ⍝ ← wildcard matches having nameclass in or below space
[10]  ⍝ Phil Last ⍝ 2008-01-22 21:26
[11]   }
     ∇

     ∇ nd←{
[1]        ⌈/-∘(⌊/)⍨+.=∘'.'⍕,[⍬]nt ⍵
[2]   ⍝ namespace depth
[3]   ⍝ ⍵ ns
[4]   ⍝ ← 0⌈⌈/1+∇¨subnss
[5]   ⍝ Phil Last ⍝ 2008-09-02 14:23
[6]    }
     ∇

     ∇ ne←{
[1]        ⍺(⍵{⍺+⍵ׯ1*(⍺-⍵)∊⍺⍺})⌊/|⍺∘.-⍵
[2]   ⍝ nearest
[3]   ⍝ ⍺ integer list
[4]   ⍝ ⍵ ditto
[5]   ⍝ ← ⍺ decreased or increased where necessary to nearest value of ⍵
[6]   ⍝      0 4 9 14 20 25 ne 3×⍳10
[7]   ⍝ 0 3 9 15 21 24
[8]    }
     ∇

     ∇ ni←{⍺←⊢ ⋄ ⍵≡⍺ ⍵:∇/⍵ ⋄ {⍵._Inst}{
[1]            (⍵._Inst.⍎⍺,'←⍵∘{0::(⊃⍬⍴⎕DM)⎕SIGNAL ⎕EN ⋄ ⍺ ⍺._Class.',⍺,'⍵}')/⍵
[2]        }/⍵,⍺{⍵⊣⍵.(_Class _Inst)←⍺,#.⎕NS''}#.⎕NS''
[3]   ⍝ ⍵ (class)(methods)
[4]   ⍝ ← instance
[5]   ⍝ class: space having at least the functions named in methods.
[6]   ⍝ methods: names of explicit dyadic functions in class.
[7]   ⍝ instance: space with derived methods that call the class
[8]   ⍝           methods that share data in their unnamed space
[9]   ⍝           left argument that refs instance and class.
[10]  ⍝ .-class-----. .-instance-. .-------------.
[11]  ⍝ | fns, data | | methods  | | data  class |
[12]  ⍝ |   methods | '--↓-------' | instance ↓  |
[13]  ⍝ '-----↓--↑--'    |   ↑     '--↓-------|--'
[14]  ⍝    ↑  |  |       |   |        |   ↑   |
[15]  ⍝    |  |  '-------'   '--------'   |   |
[16]  ⍝    |  |                           |   |
[17]  ⍝    |  '---------------------------'   |
[18]  ⍝    |                                  |
[19]  ⍝    '----------------------------------'
[20]   }
     ∇

     ∇ nm←{
[1]        ⍺←#
[2]        ,∘⍵⍣⍺.{0=⎕NC ⍺}''
[3]   ⍝ new name
[4]   ⍝ ⍺ space
[5]   ⍝ ⍵ scalar char
[6]   ⍝ ← new name undefined in space
[7]   ⍝ Phil Last ⍝ 2009-02-14 18:28
[8]    }
     ∇

     ∇ nn←nn
[1]    nn←(-(⌽⊢)⍳⊣)↑⊢
[2]   ⍝ node name
[3]   ⍝ ⍺ separator
[4]   ⍝ ⍵ name - qualified ws item, filename ?
[5]   ⍝ ← last node
[6]   ⍝ Phil Last ⍝ 2008-06-02 22:58
     ∇

     ∇ no←no
[1]    no←~∘∊⍨
[2]   ⍝ nulls out
[3]   ⍝ Phil Last 2017-12-19 07.35
     ∇

     ∇ ns←{
[1]        {⍵{⍵\{
[2]                    0::1            ⍝ ok if error!
[3]                    {0}#.⎕SRC #.⍎⍵  ⍝ wrong if not
[4]                }¨⍵/⍺
[5]            }9.1=#.⎕NC ⍵}⊂if≡⍵
[6]   ⍝ non scripted
[7]   ⍝ ⍵ nested list
[8]   ⍝ ← boolean, which of (⍵) are names of non-scripted (ordinary) nss
[9]   ⍝ Phil Last ⍝ 2008-04-15 19:04
[10]   }
     ∇

     ∇ nt←{
[1]        ∪⍵{⊃∇/⍺.(⍺{(0,⍵)/⍨0,(⍺≠⍵)∧⍺=⍵.##}⍎⍕'⍺',⌽↓⎕NL 9.1),⊂⍵,⍺}⍬
[2]   ⍝ namespace tree
[3]   ⍝ ⍵ ns
[4]   ⍝ ← ns and all nss below
[5]   ⍝   excludes nss whose only ref is outside parent
[6]   ⍝ Phil Last ⍝ 2008-04-30 00:30
[7]    }
     ∇

     ∇ os←{
[1]        f←({⍵⊣⍵.x←⍬}⎕NS'')∘{⍺.x⊣⍺.x{(⍺~⍵)∪⍵~⍺}←,⍵}
[2]        f{⍵⊣⍵.(f←⍺⍺)/0}⎕NS''
[3]   ⍝ one store
[4]   ⍝ ⍵ ? ignored
[5]   ⍝ ← ns containing function f
[6]   ⍝ after which in ns.f ⍵
[7]   ⍝   ⍵ array
[8]   ⍝   ← contents of store after call being
[9]   ⍝     items previously in store not in arg
[10]  ⍝     and items in arg not previously in store
[11]  ⍝ with the result that scalars in arg
[12]  ⍝ are added to or removed from store.
[13]  ⍝   ns.f ⍬   ←→ contents unchanged
[14]  ⍝   ns.f⍣2⊢⍬ ←→ empty store
[15]   }
     ∇

     ∇ pa←{
[1]        ⍺←⎕PW-1
[2]        {⍵↓¨⍨~1↑⍨⍴⍵}⍵{⍺⊂⍨⍵↑⍨⍴⍺}⊃,/⍺{⍵↑¨⍺ cl ⍵}¯2-/0,(⍴⍵),⍨(/∘⍳∘⍴⍨)⍵=' '
[3]   ⍝ paragraph
[4]   ⍝ ⍺ width
[5]   ⍝ ⍵ text string
[6]   ⍝ Phil Last ⍝ 2008-09-11 15:03
[7]    }
     ∇

     ∇ pb←{
[1]        bl ht nb←⎕UCS' 'HT NB
[2]        (1=≡⍵){
[3]            (↑⍣⍺)⎕UCS∘{
[4]                {⊃⍵ nb+.×0 1=⊂{⍵∧⌽∨\⌽~⍵}⍵∊ht bl}⍵/⍨6*⍵=ht
[5]            }∘⎕UCS¨(↓⍣⍺)⍵
[6]        }⍵
[7]   
[8]   ⍝ preserve blanks
[9]   ⍝ ⍵ text perhaps with leading or embedded blanks or tabs
[10]  ⍝ ← ⍵ with leading and embedded blanks and tabs replaced by
[11]  ⍝   non-breaking space(NB): ' ' 1 for 1; tab(HT) 6 for 1.
[12]   }
     ∇

     ∇ pf←{⍺←⊢
[1]        c←'R:' 'D:' 'U:' 'E:' 'Z:' 'L:' '8:'
[2]        k←'ER' 'DC' 'UC' 'ED' 'DL' 'LL' 'F8'
[3]        def←⍺ re fl↓c,⍪⊂¨k
[4]        def ⎕PFKEY ⍵
[5]   ⍝ ⍺ def - string wherein 'R:' 'D:' 'U:' 'E:'
[6]   ⍝          replaced with 'ER' 'DC' 'UC' 'ED'
[7]   ⍝ ⍵ key
[8]   ⍝ ← new defn
[9]   ⍝ Phil Last 2014-10-01 11:57
[10]   }
     ∇

     ∇ pl←{
[1]        0∊∊⍺:(⍕⍺),(⍺≠1)⊃~∘∊⍨' '(=⊂⊢)' ',⍵
[2]        (1⌽(⍵≠1)⊃~∘∊⍨{⍵⊂⍨⍵=⊃⍵}' ',⍺),⍕⍵
[3]   ⍝ plural
[4]   ⍝ ⍺  number          | ⍺  'this these'
[5]   ⍝ ⍵  'thing things'  | ⍵  number
[6]   ⍝ ←  1 thing         | ←  this 1
[7]   ⍝    n things        |    these n
[8]    }
     ∇

     ∇ pn←{⍺←'\/'
[1]        ⍵{(⍵↓⍺)(⍵↑⍺)}-⌊/(⌽⍵)⍳⍺
[2]   ⍝ file path / name  ⍝ '/' being ⍺←'/\' by default
[3]   ⍝ ⍵ file/path/name
[4]   ⍝ ← (file/path/) (name)
[5]   ⍝ path - up to and including final separator
[6]   ⍝ name - beyond final separator
[7]   ⍝ Phil Last ⍝ 2008-07-07 11:31
[8]    }
     ∇

     ∇ pp←{
[1]        len←⍴str←sz,' ',⍵
[2]        word←⌈len÷+/brk←str∊' -'
[3]        lines←⌈len÷⍺-word
[4]        wid←⌈len÷lines
[5]        pos←wid×⍳lines
[6]        pos←pos ne brk/⍳len
[7]        msk←(⍳len)∊pos
[8]        ~∘∊⍨msk⊂1⌽str
[9]   ⍝ paragraph
[10]  ⍝ 4 × quicker than pa but not guaranteed to stay within width
[11]   }
     ∇

     ∇ pr←{
[1]        ⍺←'()'
[2]        ⍺∘{1⌽(⌽⍺),⍵}ad{1}⍵
[3]   ⍝ parenthesise
[4]    }
     ∇

     ∇ ps←{
[1]        def←'⍺⍺'(cr'')
[2]        ⍺←def
[3]        arg←,es ⍺
[4]        fnx exc←2⍴arg,(⍴arg)↓def
[5]        ⍺{
[6]            ⊃,/,⍉↑{{'(',fnx,'''',⍵,''')'}¨⍵
[7]            }\⊃{⍺∘{(⍵/2</0,⍵)⊂⍵/⍺
[8]                }¨1 0=⊂(⍺=' '){⍵∨⍺∧⍵{⍵∊⍺/⍵}+\~⍺
[9]                }{(⍺ ⍺⍺ ⍵)∧⌽(⌽⍺)⍺⍺⌽⍵}⍵
[10]           }/exc ec ⍵
[11]       }{⍵/⍨1+⍵=''''}'(',⍵,')'
[12]  ⍝ parse
[13]  ⍝ ⍺ 'fnexpr' ['exechars'] - default '⍺⍺' '(~<≤=≥>≠∨∧⍱⍲)\'
[14]  ⍝ ⍵ string may contain text and executable chararacters.
[15]  ⍝   use \ to escape executable chars including itself.
[16]  ⍝ ← string parsed so that each substring is arg to fnexpr
[17]  ⍝ (this∧~and)<that ←→ (((⍺⍺'this')∧~(⍺⍺'and'))<(⍺⍺'that'))
[18]  ⍝ Phil Last ⍝ 2008-03-04 15:14
[19]   }
     ∇

     ∇ px←px
[1]    px←((,/2⍴⊢),2↓⊢)⎕NPARTS
[2]   ⍝ 'path/name.ext' → 'path/name' '.ext'
[3]   ⍝ Phil Last 2018-01-12 19.45
     ∇

     ∇ qu←{
[1]        ⍺←''''
[2]        ⍺,(⍵/⍨1+⍵=⍺),⍺
[3]   ⍝ quote
[4]   ⍝ Phil Last ⍝ 2008-01-14 17:39
[5]    }
     ∇

     ∇ rc←{
[1]        ⍺←1 1
[2]        22::⍬    ⍝ missing file
[3]        ⍺{(⎕FUNTIE ⍵)⊢{⎕FREAD ⍺ ⍵
[4]            }/⍵,⍪0~⍨⍺{⍴⍴⍺:⍵/⍨⍺⍴⍨⍴⍵ ⋄ ⍺↑⍵}⊃↓∘⍳/2⍴⎕FSIZE ⍵
[5]        }⍵ ⎕FSTIE 0
[6]   ⍝ read component file
[7]   ⍝ ⍺ scalar - larg to ↑ on components - 3=first 3, ¯2=last 2
[8]   ⍝   vector - larg to / on components used cyclically -
[9]   ⍝            (1 0)=odds, (0 0 1)=every third, default - (1 1)=all
[10]  ⍝ ⍵ file path/name
[11]  ⍝ ← vector of file components
[12]  ⍝ Phil Last ⍝ 2008-07-04 14:55
[13]   }
     ∇

     ∇ rd←{
[1]        ⊃(⌊0.5+⍵×⍺÷+/⍵){⍺⍺+⍵{(×⍵)×(⍳⍴⍺)∊(⍒|⍺)⍴⍨|⍵}⍺-+/⍺⍺}/⍺ ⍵
[2]   ⍝ redistribute
[3]   ⍝ ⍺ new scalar integer total
[4]   ⍝ ⍵ simple integer list
[5]   ⍝ ← list with length as (⍵), total as (⍺) and relative proportions similar
[6]   ⍝   to (⍵). Recalculate proportionally; round to integer; redistribute
[7]   ⍝   total error (e) as +/-1 for each of the (e) absolute largest items.
[8]    }
     ∇

     ∇ re←{
[1]        fi←{(⍴,⍺){⍵\⍺{⍵∊⊃⍺{⍵,⍺/⍨⍺≥⍺⍺+⌈/⍵}/⌽(-⍺),⍵}⍵/⍳⍴⍵}⍺⍷⍵} ⍝ no overlap
[2]        ⊃⍺{(⍴,⍵)↓⊃,/⍵∘,¨(⍴,⍺)↓¨⍺{⍵⊂⍨⍺ fi ⍵}⍺,⍺⍺}/⍵
[3]   ⍝    ⊃⍺{(⍴,⍵)↓⊃,/⍵∘,¨(⍴,⍺)↓¨⍺{⍵⊂⍨⍺ ⍷  ⍵}⍺,⍺⍺}/⍵
[4]   ⍝ replace
[5]   ⍝ string re old new
[6]   ⍝ Phil Last ⍝ 2007-12-31 11:22
[7]    }
     ∇

     ∇ rf←{
[1]        ⍺←⎕DR''
[2]        22::0/' ' 0[2|⍺]
[3]        ⍺{(⎕NUNTIE ⍵)⊢⎕NREAD ⍵,⍺,2↑⎕NSIZE ⍵}⍵ ⎕NTIE 0
[4]   ⍝ read file
[5]   ⍝ ⍺ conversion - dflt ⎕DR'' (?80?82?) - giving text
[6]   ⍝ ⍵ file path/name
[7]   ⍝ ← file body - type acc'g ⍺
[8]   ⍝   if no file - ⍬ or '' acc'g ⍺ is odd or even
[9]   ⍝ Phil Last ⍝ 2008-06-12 8:40
[10]   }
     ∇

     ∇ rm←{
[1]        ⍺{1↓⊃,/⍵{(¯1↓' ',(⍴⍵)⍴1↓⍺),¨⍵}(⊃⍵){⍺{(⍴⍺)↓¨⍵⊂⍨⍺⍷⍵}⍺,⍵}⍺},¨⍵
[2]   ⍝ replace multiple
[3]   ⍝ ⍺ text string with placeholders
[4]   ⍝ ⍵ list of strings first of which is placeholder the rest being strings
[5]   ⍝   to replace each placeholder, re-used cyclically if insufficient.
[6]   ⍝ ← amended string
[7]   ⍝   If 2=⍴⍵ this is equivalent to: ⍺ re ⍵
[8]   ⍝ Phil Last ⍝ 2008-06-09 23:58
[9]    }
     ∇

     ∇ rn←{⍺←⊢
[1]        ⊃if(0∘=∘⍴∘⍴){⍵↑¨⍨{+/(⍵≠' ')∧2>+\'.'=⍵}↑⍵}⊂if≡⍵
[2]   ⍝ ⍵ name(s)      '#.a.b.c.d' '#.x.y.z'
[3]   ⍝ ← rootname(s)  '#.a' '#.x'
[4]   ⍝ depth 1 or 2
[5]    }
     ∇

     ∇ rp←{
[1]        ⍵↓⍨(≢⍺)×⍺≡(≢⍺)⍴⍵
[2]   ⍝ remove prefix ⍺ from ⍵
[3]   ⍝ 'ABC' rp ⎕A → 'DEFGHIJKLMNOPQRSTUVWXYZ'
[4]   ⍝ 'abc' rp ⎕A → 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'
[5]    }
     ∇

     ∇ rs←{
[1]        f←⊢(/⍨)(1+1∊'#⎕'∊⊢)>(+\'.'=⊢)
[2]        0=10|⎕DR ⍵:f ⍵
[3]        ⍎f⍕⍵
[4]   
[5]   ⍝ root space
[6]   ⍝ ⍵ ref or fqn
[7]   ⍝ ← ref or fqn as ⍵
[8]   ⍝   if ⍵ is #, ⎕se, #.sub or ⎕SE.sub
[9]   ⍝       then ⍵
[10]  ⍝   else (# or ⎕SE).sub that contains ⍵
[11]  ⍝ longest prefix containing less than two dots
[12]   }
     ∇

     ∇ ru←{0::''
[1]        1↓⊃,/(⎕UCS 13),¨0⊃'UTF-8'⎕NGET ⍵ 1
[2]   ⍝ read unicode
[3]   ⍝ ⍵ filepath
[4]   ⍝ read UTF-8 file with CR (U+000D)
[5]    }
     ∇

     ∇ sa←{
[1]        b←=∘⍵⍣(0=≡⍺)⊢⍺
[2]        1↓¨(1,b)⊂' ',⍵
[3]   ⍝ split at
[4]   ⍝ ⍺ scalar char or boolean length of ⍵
[5]   ⍝ ⍵ string
[6]   ⍝ ← ⍵ split at 1s in ⍺ or where ⍵=⍺
[7]    }
     ∇

     ∇ sc←{
[1]        ⍺←⊢
[2]        sc←{⍺←⊢
[3]            (0∊⍴r←⍺ fi ⍵):0 2⍴r
[4]            r←r/⍨1=≡∘vr¨r
[5]            {(+/∨\' '≠⌽⍵)↑⍵}¨↑{⍵⊂⍨{⍵∧2≥+\⍵}2</0,⍵≠' '
[6]            }¨⊃,/'' '',(⊃ec ⍵)∘{⍵∘,¨⍺∘{⍵/⍨⍺∘{1∊⍺⍷⍵}¨⍵}≠∘CR pt vr ⍵}¨r
[7]        }
[8]        1=≡⍵:⍺ sc ⍵
[9]        ↑∪↓⊃⍪/⍺∘sc¨⍵
[10]  ⍝ search & show
[11]  ⍝ ⍺ & ⍵ args to fi but ⍵ has to be a simple positive search so the entire
[12]  ⍝ string is to be found as is within the target. No logical wildcards.
[13]  ⍝ All potential control chars to be escaped.
[14]  ⍝ ← each line of each item that contains the string.
[15]   }
     ∇

     ∇ se←{
[1]        fac←∇{⍵≤9:2 ⋄ ⍺⍺⌈⍵*÷2}⍵
[2]        res←~⍵↑1 1
[3]        res/⍳⍵⊣⍵{
[4]            ⊢res[⍵×⍵↓⍳⌈⍺÷⍵]←0
[5]        }¨fac
[6]   ⍝ sieve of Eratosthenes
[7]   ⍝ was ...
[8]        n←24 60 60 1000
[9]        td←{(#.DateToIDN 3⍴⍵)+(n⊥3↓⍵)÷×/n}
[10]       dt←{(3⍴#.IDNToDate⌊⍵),⌊n⊤(1|⍵)××/n}
[11]       (dt(td ⎕TS)-(⌈/⎕AI)÷×/n)((0,n)⊤⌈/⎕AI)
[12]  ⍝ session start & duration
[13]  ⍝ ⍵ null
[14]  ⍝ ← start: y m d h m s m, duration: d h m s m
[15]  ⍝ Phil Last ⍝ 2008-02-04 18:13
[16]   }
     ∇

     ∇ sf←{
[1]        ⎕ML←0
[2]        aA0←(~∘' ''',(/⍨∘(≠\∘(''''∘=))⍨ps ⍵),ab'')∘{⍵{⍵\⍵/⍺}⍵∊⍺}
[3]        ⍺←#
[4]        0::((⊃⎕DM),' - Try escaping "',(⍵∩'(~<≤=≥>≠∨∧⍱⍲)\'),'"')⎕SIGNAL ⎕EN
[5]        ('1∊⍵⍷⍨'ps ⍵){⍵/⍨⍺∘{⍺{⍎⍺}aA0,⍕⍵{
[6]                    (⍵∊3 4):⎕VR ⍺
[7]                    (⍵=2):⍎⍺
[8]                    (⍵=9):⎕SRC⍎⍺
[9]                    ''
[10]               }⎕NC ⍵}¨⍵}{
[11]           (''≢0⍴⍵):⍵ li 3 4 9.4
[12]           ⍵ lf # li 3 4 9.4
[13]       }⍺
[14]  ⍝ syntax find
[15]  ⍝ ⍺ ref    - search all in or below
[16]  ⍝   string - wildcard selection of candidates anywhere
[17]  ⍝ ⍵ search string - can contain executables "(~<≤=≥>≠∨∧⍱⍲)". see ps
[18]  ⍝ ← fully qualified names of arrays, fns, ops & classes where found.
[19]  ⍝ Phil Last ⍝ 2008-03-12 19:30
[20]   }
     ∇

     ∇ sg←{
[1]        ⍵{⍵×⌊0.5+⍺÷⍵}10*-⍺-1+⌊10⍟|⍵+⍵=0
[2]   ⍝ significant figures
[3]   ⍝ ⍺ int(s)
[4]   ⍝ ⍵ float(s)
[5]   ⍝ ← (⍵) "rounded" to (⍺) sig figs
[6]   ⍝ this is a scalar function
[7]   ⍝ Phil Last ⍝ 2008-08-01 10:29
[8]    }
     ∇

     ∇ sh←{
[1]        {w}'w'⎕WC w←'OLECLIENT' 'WScript.Shell'
[2]   ⍝ windows shell object
[3]   ⍝ ⍵ ?
[4]   ⍝ ← windows shell object
[5]    }
     ∇

     ∇ si←{⍺←⊢
[1]        {⍺,,('P<[>Q<]>I',⍕3+⌊10⍟1⌈⍵)⎕FMT ⍵}/1↓⍉↑⎕XSI ⎕LC
[2]   ⍝
[3]   ⍝ Phil Last 2017-12-05 20.15
[4]    }
     ∇

     ∇ sl←sl
[1]    sl←⊣(1↓¨=⊂⊢),
[2]   ⍝ separated string to list without sep
[3]   ⍝ nilad returning dyad
[4]   ⍝ Phil Last 2017-12-19 07.35
     ∇

     ∇ sm←{⍺←⊢
[1]        (ns<9<⎕NC)sp¨⊂if≡⍵
[2]   ⍝ script member
[3]   ⍝ Phil 2018-01-28 18.16
[4]    }
     ∇

     ∇ sn←sn
[1]    ns<9≤⎕NC
[2]   ⍝ ⍵ fqns
[3]   ⍝ ← boolean which are scripted spaces
     ∇

     ∇ so←{
[1]        ⍵⊣(⎕NS'').(⎕ED&{'n'}n←⍕1 ##.ty↑n∘,¨↓'.',⍵.⎕NL 2 3 4⊣n,←'s'/⍨~n/⍨←~'['∊n←⍕s←⍵)
[2]   ⍝ edit all objects in space:
[3]   ⍝ Phil Last ⍝ 2008-03-12 08:32
[4]    }
     ∇

     ∇ sp←sp
[1]    sp←1⊃⎕NPARTS
[2]   ⍝ space path
[3]   ⍝ monad
[4]   ⍝ '#.a.b.c' → '#.a.b'
[5]   ⍝ '#.a.b'   → '#.a'
[6]   ⍝ '#.a'     → '#'
[7]   ⍝ '#'       → '#'
     ∇

     ∇ sq←{
[1]        ⍺←1
[2]        cols←1⌈⌊0.5+{(⌈(⍺×⍵)*÷2)÷⍵}/⍺ 1×2 1×⍴⍵
[3]        ↑,/⍉cols rows⍴(cols×rows←⌈(⍬⍴⍴⍵)÷cols)↑↓⍵
[4]   ⍝ square
[5]   ⍝ reshape text column to nearest ⍺ rectangular display
[6]   ⍝ default square (1) - 2 gives 2×width
[7]    }
     ∇

     ∇ su←{ft'⍝- '
[1]   ⍝- :Class suicide
[2]   ⍝-     ∇ inst←New(fn arg)
[3]   ⍝-       :Access public shared
[4]   ⍝-       inst←(⍬⍴⎕RSI).⎕NEW ⎕THIS
[5]   ⍝-     ∇
[6]   ⍝-
[7]   ⍝-     ∇ coroner
[8]   ⍝-       :Implements destructor
[9]   ⍝-       (##.⍎fn)arg
[10]  ⍝-     ∇
[11]  ⍝- ⍝ set a destructor on an ordinary container space.
[12]  ⍝- ⍝ call as:  condemned.inst←suicide.New fn arg
[13]  ⍝- ⍝    named fn (accessible from space calling New) will be
[14]  ⍝- ⍝    applied to arg when space - condemned - is destroyed.
[15]  ⍝- ⍝ Phil Last ⍝ 2013-06-29 10:31
[16]  ⍝- :EndClass
[17]   }
     ∇

     ∇ sv←{⍺←⊢
[1]        q←⊃(⍺,⍵,q)∩q←'"'''
[2]        w←⍵\⍨{~≠\⍵/⍨1+⍵}∨/¯1 0⊖(⊢(>,⍤0∧)≠\)⍵=q
[3]        ~∘q¨~∘∊⍨{1↓¨⍵⊂⍨(⍵=' ')>≠\q=⍵}' ',w
[4]   ⍝ blank separated string to vector of words and quoted substrings
[5]   ⍝ [⍺] override quote
[6]   ⍝ ⍵ string
[7]   ⍝ ← list of "words" which may include quoted blanks.
[8]   ⍝ quote is first encountered of '"' and "'"
[9]   ⍝ unless overridden by ⍺ and all are removed.
[10]  ⍝ '1 23 asd "two words"' → '1' '23' 'asd' 'two words'
[11]   }
     ∇

     ∇ sw←{
[1]        ⍺←#
[2]        sw←{(2↓⊃,/' ','∨',¨⍺ sf' ',⍵,' ')sc ⍵}
[3]        1=≡⍵:⍺ sw ⍵
[4]        ↑∪↓⊃⍪/⍺∘sw¨⍵
[5]   ⍝ search word
[6]   ⍝ ⍺ target ns
[7]   ⍝ ⍵ target word
[8]   ⍝ ← all occurrences including as a substr
[9]   ⍝   in items that contain the word alone
[10]   }
     ∇

     ∇ sx←{
[1]        ⍺←⊢
[2]        s←⊃{⍺,'∨',⍵}/⍺ fi ⍵
[3]        t←{1↓¨⍵⊂⍨⍵=''''}{⍵/⍨≠\⍵=''''}ps ⍵
[4]        {⍵⌿⍨~>/'⍝'=↑⊢/⍵}↑∪↓⊃⍪/s∘sc¨t
[5]   
[6]   ⍝ search executable (not in comments
[7]    }
     ∇

     ∇ sz←{⍺←⊢
[1]        c←⍺⊣' '
[2]        ⍵/⍨~(2⍴c)⍷⍵
[3]   ⍝ squeeze
[4]   ⍝ [⍺] alternative char to blank
[5]   ⍝ ⍵ string
[6]   ⍝ ← ⍵ without multiple char. Single leading and trailing not removed.
[7]   ⍝ Phil Last ⍝ 2008-01-13 12:22
[8]    }
     ∇

     ∇ tb←{
[1]        ⍵↓⍨-+/∧\' '=⌽⍵
[2]        ⍵↓⍨-⊥⍨⍵=' '
[3]   ⍝ remove trailing blanks
[4]   ⍝ ⍵ string
[5]   ⍝ ← ⍵ ~ trailing blanks
[6]   ⍝ Phil Last ⍝ 2008-01-15 00:55
[7]    }
     ∇

     ∇ tc←{
[1]   ⍝     maj←min←+
[2]   ⍝     z←'maj' 'min'{⍺ ⎕NA'I4 USER32.C32|Char',⍵,'* =0T'}¨'Upper' 'Lower'
[3]   ⍝     case←{(⍴⍵)⍴⊃⌽⍺⍺⊂,⍵}
[4]        maj min←1 0
[5]        ⍺←2
[6]        ⍺=1:min cc ⍵
[7]        ⍺=2:maj cc ⍵
[8]        f←{
[9]            ⍺=1:min cc ⍵
[10]           ⍺=2:maj cc ⍵
[11]           ⍺=3:⍵{(⍴⍺)⍴(2</0,≠⌿⍵)⊖⍵}↑(1 ∇ ⍵)(2 ∇ ⍵)
[12]           ⍺≠3:⍵{(⍴⍺)⍴(⍺=(⍴⍺)⍴⍵)⊖⍵}↑(1 ∇ ⍵)(2 ∇ ⍵)
[13]       }
[14]       1≠≡⍵:⍺∘f¨⍵
[15]       ⍺ f ⍵
[16]  ⍝ type case
[17]  ⍝ ⍺ 1 - convert to minuscule
[18]  ⍝ ⍺ 2 - CONVERT TO MAJUSCULE - dflt
[19]  ⍝ ⍺ 3 - Capitalise - convert to minuscule;
[20]  ⍝                    Initials To Majuscule
[21]  ⍝       otherwise SWITCH case
[22]  ⍝ ⍵ simple text array or depth 2 or ¯2
[23]  ⍝ ← ⍵ converted according ⍺
[24]  ⍝ Phil Last ⍝ 2008-01-22 21:26
[25]   }
     ∇

     ∇ tl←{
[1]        s←⍴⍵                    ⍝ shape
[2]        k←≢s                    ⍝ rank
[3]        c←1+(-k)↑¯1+⍺           ⍝ cell
[4]        ⊃{s k c←⍺               ⍝ per dim
[5]            ↑(s⍴c↑1)∘(⊂[k])¨⍵   ⍝ partition
[6]        }/(⌽↓s,(⍳k),⍪c),⊂⊂⍵     ⍝ fold left
[7]   ⍝ tessellate
[8]   ⍝ ⍺ shape of sub arrays
[9]   ⍝ ⍵ multi-d array
[10]  ⍝ ← nested array of ⍺ shaped subarrays of ⍵
[11]  ⍝   if ⍺ is shorter than rank ⍵ it is padded at left with ones.
[12]  ⍝   if any ⍺ is not a factor of the corresponding item of ⍴⍵,
[13]  ⍝       trailing cells are truncated.
[14]   }
     ∇

     ∇ tm←{
[1]        n←1≠≡⍵
[2]        d←,⊂⍣n,'...'
[3]        o←⍴d
[4]        f←⌽⍣(⍺<0)
[5]        w←(|⍺)⌊⍴⍵
[6]        t←w<⍴⍵
[7]        1:f w⍴((w-t×o)↑f ⍵),d
[8]        ((|⍺)⌊⍴⍵)(⌽⍣(⍺<0)){⍺⍺ ⍺{⍺⍴(⍵⍴⍨⍺-3×⍺<⍴⍵),(⍳1=≡⍵)⊃3 2 1⍴¨'.'}⍺⍺ ⍵}⍵
[9]   ⍝ truncate message or list
[10]  ⍝    10 ¯10 9 ¯9 tm¨⊂⎕D
[11]  ⍝ 0123456789  0123456789  012345...  ...456789
[12]  ⍝    nms← 'one' 'two' 'three' 'four' 'five' 'six' 'seven' 'eight' 'nine' 'ten'
[13]  ⍝    ⍪ 8 ¯8 tm¨⊂nms
[14]  ⍝ one  two  three  four  five  six  seven  ...
[15]  ⍝ ...  four  five  six  seven  eight  nine  ten
[16]   }
     ∇

     ∇ tp←{
[1]        ⎕THIS.tp←⍎(×⎕ML)⊃'∊' '⊃∘(⍬∘⍴)∘(0∘⍴)∘⊂'
[2]        tp ⍵
[3]    }
     ∇

     ∇ tr←{
[1]        {(+/∧\' '=⍵)↓⍵}∘⌽⍣2⊢⍵
[2]        ⍵/⍨{(∨\⍵)∧⌽∨\⌽⍵}⍵≠' '
[3]   ⍝ trim leading and trailing blanks
[4]    }
     ∇

     ∇ tv←{
[1]        n←⎕NS''
[2]        w d←ht es ⍵
[3]        n.d←d
[4]        {(+/∨\' '≠⌽⍵)↑¨↓⍵}n ⍺.{
[5]            (⊂⍵)∊⍺.d:⍵
[6]            ⍺.d,←⊂⍵
[7]            f←(~∘' '¨↓(⊢(⌿⍨)3 4∊⍨⎕NC)⎕REFS ⍵)~⊂⍵
[8]            ⍕⍵,⊂'|',⍕⍪∇/⍺,⍪f
[9]        }w
[10]  ⍝ tree view of function calls
[11]  ⍝ ⍺ namespace wherein -
[12]  ⍝ ⍵ function/operator-name
[13]  ⍝ ← (large) nested text array
[14]   }
     ∇

     ∇ ty←{
[1]        ⍺←0
[2]        ⍺{
[3]            (dim pw)←2⍴⍺,(⍴,⍺)↓0,⎕PW
[4]            sw←dim≠0
[5]            len wid←⍴⍵
[6]            cols←1⌈⌊|pw÷wid+2
[7]            rows←⌈len÷cols
[8]            len←cols×rows
[9]            (⍒sw×⍳2)⍉(sw⌽rows cols)⍴↓len wid↑⍵
[10]       }↑,↓↑⍵
[11]  ⍝ tidy
[12]  ⍝ ⍵ 2d or nested list - names - whatever
[13]  ⍝ ← 2d text in columns
[14]  ⍝ Phil Last ⍝ 2008-03-02 19:21
[15]   }
     ∇

     ∇ uc←{
[1]        1 ll ⍵
[2]   ⍝ upper case clone
[3]   ⍝ ⍵ space with vars
[4]   ⍝ ← space as ⍵ but all vars are upper case
[5]    }
     ∇

     ∇ um←{
[1]        (⍵⍳⍵)=⍳⍴⍵
[2]   ⍝ unique mask
[3]   ⍝ ⍵ vector
[4]    }
     ∇

     ∇ ur←{
[1]        fqn←⍵ li 3.1 3.2 4.1 4.2
[2]        refs←{(+/∨\' '≠⌽⍵)↑¨↓⍵}∘⎕REFS¨fqn
[3]        all←
[4]   ⍝ unreferenced names
[5]   ⍝ ⍵ space?
[6]   ⍝ ← fqn ref - corresponding FQN and unref'd word
[7]   ⍝ Phil Last 2017-05-18 08.40
[8]    }
     ∇

     ∇ us←{⍺←⊢
[1]        ('n'⎕NS ⍵)⊢n←⍎⍣(1≢⍺ 1)⊢⍺ #.⎕NS''
[2]   ⍝ unscript
[3]   ⍝ [⍺] optional fqn for result
[4]   ⍝  ⍵  scripted space
[5]   ⍝ ← [named] space containing first level members of space
[6]   ⍝ Phil Last 2015-04-22
[7]    }
     ∇

     ∇ uu←{
[1]        ⍺←#
[2]        ⍺{⍵/⍨⍵{0∊⍴⍵~⊂⍺}¨⍺ sf¨{' ',⍵,' '}∘('.'∘nn)¨⍵}(/⍨)∘(0∘<∘⎕NC)⍨⍵ li 3 4
[3]   ⍝ unused
[4]   ⍝ ⍺ space to search - dflt #
[5]   ⍝ ⍵ space to list
[6]   ⍝ ← fns & ops in (⍵) NOT called from anywhere in (⍺)
[7]    }
     ∇

     ∇ vc←{⍺←CR
[1]        1↓⍺{⍵/⍨~(3⍴⍺)⍷⍵}{(,⌽∨\⌽⍵≠' ')/,⍵}⍺,⎕FMT cm⍣(1≠≡⍵)⊢⍵
[2]   ⍝ varchar
[3]   ⍝ ⍵ char array - more or less any
[4]   ⍝ ← [newline] delimited string
[5]   ⍝   no trailing blanks in substrings of which no consecutive empties
[6]    }
     ∇

     ∇ vr←{
[1]        2=⎕NC ⍵:{
[2]            1 1≡(≡⍵),⍴⍴⍵:⍵
[3]            1↓⊃,/CR,⎕FMT ⍵
[4]        }⍎⍵
[5]        3 4∨.=⎕NC ⍵:⎕VR ⍵
[6]        0::'∇ ','.'nn ⍵
[7]        {1↓⊃,/,/CR,('P<[>Q<]>LI6'⎕FMT⍳⍴⍵),⍵}⎕SRC⍎⍵
[8]   ⍝ vector representation of function/operator/class/namespace
[9]    }
     ∇

     ∇ wf←{
[1]        ⍺{(⎕NUNTIE ⍵)⊢⍺ ⎕NAPPEND ⍵,⎕DR ⍺}{
[2]            22::0 ⎕NRESIZE ⍵ ⎕NTIE 0
[3]            ⍵ ⎕NCREATE 0
[4]        }⍵
[5]   ⍝ write file
[6]   ⍝ ⍺ data in form it can be written as-is - char or num vec
[7]   ⍝ ⍵ file path/name if exists is resized to zero first
[8]   ⍝ ← bytes written
[9]   ⍝ Phil Last ⍝ 2008-06-12 8:40
[10]   }
     ∇

     ∇ wi←{
[1]        ⎕ML←0
[2]        ⊃∧/(' ',⍺,' ')∘{∨/⍵⍷⍺}¨{⍵{(⍵/⍵>¯1↓0,⍵)⊂⍵/⍺}⍵≠'*'}{⍵{(⊃⍵)⌽⍺,⍨⍵/' '}2⍴¯1⌽'*'≠⍵}tr ⍵
[3]   ⍝ wild
[4]   ⍝ ⍺ text table
[5]   ⍝ ⍵ wild card - one of - '*' 'pre*' '*mid*' 'pre*mid*' '*end' 'pre*end' '*mid*end' 'pre*mid*end'
[6]   ⍝ ← boolean per row matches
[7]   ⍝ Phil Last ⍝ 2008-01-07 09:19
[8]    }
     ∇

     ∇ wp←{
[1]        s←0⊃'\/'{(⍵∩⍺),⍺}ws←⎕WSID
[2]        (w p)←ws{(⍵↓⍺)(⍵↑⍺)}-(⌽ws)⍳s
[3]        ((0∊⍴w)⊃w('.',s))((p⍳'.')↑p)
[4]   ⍝ path/name of ⎕wsid
[5]   ⍝ e.g.
[6]   ⍝ ⎕wsid ←→ 'C:\FlipDB\Wss\Acne.DWS'
[7]   ⍝ ←        'C:\FlipDB\Wss\' 'Acne'
[8]   ⍝ ⎕wsid ←→ 'Acne.DWS'
[9]   ⍝ ←        '' 'Acne'
[10]   }
     ∇

     ∇ ws←{
[1]        nsn←{⊃⍵~⍨'f'∘,∘⍕¨⍳1+⍴⍵}~∘' '¨↓#.⎕NL⍳10 ⍝ named in root e.g. 'f0'
[2]        cpy←⍎nsn ⎕NS''                       ⍝ create it - cpy is ref
[3]        sws sns←⍵                              ⍝ source ws & ns
[4]        z←sns{6::0 ⋄ +{}⍺ cpy.⎕CY ⍵}sws        ⍝ ← populate ref
[5]        rfs nss/⍨←⊂ns⊢nss←⍕¨rfs←1↓nt cpy     ⍝ named non scripted ns-tree
[6]        tns←(⍕⍺)∘,¨(2+⍴nsn)↓¨nss               ⍝ swap to target prefix (⍺)
[7]        tns←⊃rfs.{⍵ ⎕NS ⎕NL 2 3 4}tns          ⍝ copy vars fns & ops for each ns
[8]        {tns}#.⎕EX nsn                         ⍝ lose global root ns 'f0'?
[9]   ⍝ wscopy
[10]  ⍝ ⍺ ref of namespace in active ws (obviously)
[11]  ⍝ ⍵ two strings (wspath)(nspath)
[12]  ⍝ ← name of namespace being the name of the target parent (⍺)
[13]  ⍝   followed by the final node of the source path
[14]  ⍝   only contents of named & non-scripted nss are copied.
[15]  ⍝   Items in target but not in source are kept.
[16]  ⍝ e.g. '#.one.two.three' ws 'c:\wss\that' '#.AAA.BBB'
[17]  ⍝ #.one.two.three.BBB
[18]   }
     ∇

     ∇ wu←{
[1]        ⊢⍺'UTF-8' 13 ⎕NPUT ⍵ 1
[2]   ⍝ write unicode
[3]   ⍝ ⍺ simple text with CR (U+000D)
[4]   ⍝ ⍵ filepath
[5]   ⍝ write UTF-8 file
[6]    }
     ∇

     ∇ xc←{⍺←⊢
[1]        char←⍬⍴⍺⊣NB
[2]        {⊢/(⍵=' ')⌽char,⍪⍵}⍵{(~⊃⍵)↓⍵\⍺}{(1+⍳⌈/⍵)∊⍵}+\1+{⍵>¯1↓0,⍵}⍵∊⎕A
[3]   ⍝ expand camel case name
[4]   ⍝ not before capital initial
[5]   ⍝ not between multiple caps
[6]   ⍝       xc'MrJJSmithLivedHere'
[7]   ⍝ Mr JJSmith Lived Here
[8]    }
     ∇

     ∇ xn←{⍺←⊢
[1]        (⎕NC,∘⊂∘↑⌸⊢)↓(df ⍵),⍤1⊢'.',⍵.⎕NL⍳11
[2]   ⍝ extended namelist
[3]   ⍝ fqns for each nc in space ⍵
[4]    }
     ∇

     ∇ ad←{⍺←⊢
[1]        d←1≢⍺ 1                ⍝ dyadic?
[2]        (|≡⍺ ⍵)>d+|⍵⍵⊣⍵:⍺ ∇¨⍵  ⍝ if dyad, juxtaposition of ⍺ ⍵ adds 1 to |≡
[3]        ⍺ ⍺⍺ ⍵
[4]   ⍝ at depth
[5]   ⍝ ⍺ [array]
[6]   ⍝ ⍵ array
[7]   ⍝ ⍺⍺ function to run at ...
[8]   ⍝ ⍵⍵ depth or {depth}
[9]   ⍝ ← ⍺ ⍺⍺ ⍵ or ⍺(⍺⍺ ad ⍵⍵)¨⍵ if arg(s) too deeply nested
[10]  ⍝ Phil Last ⍝ 2008-07-04 09:14
[11]   }
     ∇

     ∇ am←{⍺←⊢
[1]        W⊣W[i]←⍺ ⍺⍺⊣W[i←(⊂⍴W)|⍵⍵⊣⍳⍴W←⍵]
[2]   ⍝ amend - [⍺](mod amend sel)⍵
[3]   ⍝ [⍺] larg to ⍺⍺
[4]   ⍝ ⍺⍺  modifier of selection of ⍵ or replacement thereof
[5]   ⍝ ⍵⍵  selection function on ⍳⍴⍵ or selection thereof
[6]   ⍝ ⍵   data to be amended
[7]    }
     ∇

     ∇ as←{
[1]        (2>0⊥⍴⍵):⍵
[2]        ⌽↑⍺⍺{(⊂(⊃⍵)⍺⍺ ⍺),⍵}/⌽(⊂∘⊃¨↓⍵),↑1↓¨↓⍵
[3]   ⍝ associative scan
[4]   ⍝ ⍺⍺ dyad
[5]   ⍝ ⍵ array
[6]   ⍝ ← last dimension associative ⍺⍺ scan of ⍵
[7]   ⍝   ⍺⍺ as w x y z ←→ w (w ⍺⍺ x) ((w ⍺⍺ x)⍺⍺ y) (((w ⍺⍺ x)⍺⍺ y)⍺⍺ z)
[8]   ⍝   so can be calculated in a single left to right sweep
[9]   ⍝ Phil Last ⍝ 2008-03-04 15:03
[10]   }
     ∇

     ∇ ax←{⍺←⊢
[1]        mon←1≡⍺ 1
[2]        rx←mon⊃2⌽(mx lx rx)←,¨⌽3⍴⌽⍵⍵
[3]        pre←{k←⍴⍴⍺
[4]            ×⍴f←⍵~⌊⍵:(⍺⍴⍨1+(¯1+⍴⍺)\⍨~(⍳k+⍴f)∊⌈f)∇⌈⍵++/⍵∘.>f
[5]            (×⍵)≡,¯1:⍺ ∇(⍳k)~|⍵
[6]            t←⍋⍒(⌽⍵)⍳⍳k
[7]            ⍺ t
[8]        }
[9]        post←{(⍋⍋(⍴⍴⍵)↑1+⍋⍺)⍉⍵}
[10]       (ra rt)←⍵ pre rx
[11]       mon:rt post ⍺⍺⍤(⍴rx)⊢rt⍉ra
[12]       (la lt)←⍺ pre lx
[13]       (la ra)←lt rt⍉¨la ra
[14]       (lc rc)←⊃∘⍴¨lx rx
[15]       (lr rr)←⊃∘⍴∘⍴¨la ra
[16]       r←la ⍺⍺⍤lc rc⊢ra
[17]       t←(⍳∘(⌈/)⍨lr rr)⊃lt rt
[18]       t post r
[19]  ⍝ axis
[20]  ⍝ ⍺  optional left arg
[21]  ⍝ ⍺⍺ function to apply
[22]  ⍝ ⍵⍵ axes treated as ⌽3⍴⌽⍵⍵
[23]  ⍝ ⍵  right arg
[24]  ⍝ Each item of ⍵⍵ can be a scalar or vector of zero or more
[25]  ⍝   elements. A negative scalar n represents (⍳⍴⍴arg) ~ |n.
[26]  ⍝   A fractional axis f inserts a new unit dimension between
[27]  ⍝   ⌊f and ⌈f in the argument's shape.
[28]  ⍝ Arguments ⍺ & ⍵ are transposed to bring specified axes
[29]  ⍝   within the scope of the rank operator where they define
[30]  ⍝   the cells to which function ⍺⍺ will be applied.
[31]  ⍝ The result is transposed in an attempt to replace the axes
[32]  ⍝   in the positions they occuplied in the original argument
[33]  ⍝   of the higher rank.
[34]   }
     ∇

     ∇ ba←{
[1]        ⍺ ⍺⍺{2⊥⍺⍺/2⊥⍣¯1⊢⍺,⍵}¨⍵
[2]        2⊥⍺⍺/2⊥⍣¯1⊢⍺,[⎕IO-0.1]⍵
[3]   ⍝ binary arithmetic
[4]    }
     ∇

     ∇ cf←{⍺←⊢
[1]        {11::⌊/⍳0 ⋄ ÷/⍵}1(⊢∘(⍺∘⍺⍺)∘⍵){
[2]            ⊃∇/⍺{
[3]                (1000<+/⍵)↓(2×⍺)⍵
[4]            }(⍬⍴2↓⎕AI-(⊢∘⍺⍺/⍳1+⍺)⊢⎕AI)(⍬⍴2↓⎕AI-(⊢∘⍵⍵/⍳1+⍺)⊢⎕AI)
[5]        }(⊢∘(⍺∘⍵⍵)∘⍵)1
[6]   ⍝ compare
[7]   ⍝ a f cf g w ←→ (a f time w) ÷ a g time w
[8]   ⍝   f cf g w ←→ (  f time w) ÷   g time w
[9]   ⍝ Phil Last ⍝ 2007-06-23 20:07
[10]   }
     ∇

     ∇ cf0←{
[1]        ⍺←⊢ ⋄ a←⍺ ⋄ w←⍵ ⋄ f←⍺⍺ ⋄ g←⍵⍵
[2]        (↑'⍺ ⍺⍺ ⍵' '⍺ ⍵⍵ ⍵'),0 7↓cmpx'a f w' 'a g w'
[3]    }
     ∇

     ∇ cond←{⍺←⊢ ⋄ (1=⍺⊣0):⍺⍺⊣⍵ ⋄ (0=⍺⊣1):⍵⍵⊣⍵ ⋄ (1 ⍺⍺ ⍵):0 ⍺⍺ ⍵ ⋄ ⍵⍵⊣⍵}
     ∇

     ∇ cp←{
[1]        ⍺←⍵
[2]        ⍺∘.⍺⍺ ⍵
[3]   ⍝ MUCH quicker if ⍺⍺ is not primitive even with ¨
[4]        (⍉((⍴⍵),⍴⍺)⍴⍉⍺)⍺⍺((⍴⍺),⍴⍵)⍴⍵
[5]   ⍝ MUCH quicker with multiple identical items and pure function ⍺⍺
[6]        i j←∪∘,¨⍺ ⍵
[7]        (i⍳⍺)(j⍳⍵)⌷i∘.⍺⍺ j
[8]   ⍝ cartesian product
[9]   ⍝ Phil Last ⍝ 2006-10-02 20:29
[10]   }
     ∇

     ∇ cs←{
[1]        ⍺←⍵
[2]        ⍵ ⍺⍺{⍵ ⍺⍺(⍴⍵)⍴⍺}⍉(⌽(⍴⍺),⍴⍵)⍴⍉⍺
[3]   ⍝ cartesian product of scalar function
[4]   ⍝ Phil Last ⍝ 2007-06-17 10:33
[5]    }
     ∇

     ∇ do←{
[1]        (⍵⍵ if ⍺⍺)⍵
[2]   ⍝ [if] antecedent [then] do consequent [else do nothing]
[3]   ⍝ see if
[4]    }
     ∇

     ∇ dv←{⍺←⊢
[1]        ⍕{
[2]            ⊃,/{
[3]                0=≡⍵:⍵
[4]                0∊⍴⍵:((''⍬ ⍵)⍳⊂⍵)⊃'''''' '⍬'⍵
[5]                1=≡⍵:'(',,∘')'⊃,/,⍵
[6]                ⊃,/'(',,∘')'∇¨⍵
[7]            }⍵
[8]        }⎕CR(f←⍺⍺)/'f'
[9]   ⍝ ⍺⍺    derv
[10]  ⍝ ←     executable text-string representation of ⍺⍺
[11]  ⍝ sometimes adds too many parens but would need MUCH more analysis not to
[12]   }
     ∇

     ∇ ea←{
[1]        f←⍺⍺
[2]        ⍺←(f←⊢∘⍺⍺)/0
[3]        f⌿⍺,[-0.1]⍵
[4]   ⍝ each
[5]   ⍝ [⍺] ⍵-conformable array
[6]   ⍝ ⍵   array
[7]   ⍝ ⍺⍺  function to apply to each item of ⍵ or
[8]   ⍝     between corresponding items of ⍺ and ⍵
[9]   ⍝     but no spurious application to empties
[10]   }
     ∇

     ∇ ei←{
[1]        ⍺←⊢
[2]        (1=≡⍵):⍺ ⍺⍺ ⍵
[3]        ⍺ ⍺⍺¨⍵
[4]   ⍝ each if not simple
[5]   ⍝ ⍺ ?
[6]   ⍝ ⍵ ?
[7]   ⍝ ⍺⍺ function to run on simple ⍵
[8]   ⍝ ← [⍺]⍺⍺ ⍵ or [⍺]⍺⍺¨⍵ but not recursively
[9]    }
     ∇

     ∇ el←{
[1]        ⍺:⍺⍺⊣⍵
[2]        ⍵⍵⊣⍵
[3]   ⍝ r←(proposition consequence el alternative ⊢)⍵
[4]   ⍝ r←{proposition ⍵: consequence⊣⍵ ⋄ alternative⊣⍵}⍵
[5]   ⍝ :If proposition ⍵ ⋄ r←consequence⊣⍵ ⋄ :Else ⋄ r←alternative⊣⍵ ⋄ :EndIf
[6]   ⍝ proposition, consequence and alternative all monads on ⍵
[7]   ⍝    or consequence and alternative may be arrays.
[8]   ⍝ ⍵ in domain of proposition and functions consequence and alternative
[9]   ⍝ ← result of consequence or alternative according proposition
[10]   }
     ∇

     ∇ r←(f ep)r
[1]   ⍝ en passant
[2]    f r
     ∇

     ∇ et←{ ⍝ and
[1]        ⍺⍺⊣⍵:⍵⍵ ⍵ ⋄ 0
[2]   ⍝ f0 et f1 et f2 et ... ⍵
[3]   ⍝ ⍵ any array in domain of f0
[4]   ⍝   f0 f1 f2 &c. are monadic tests on ⍵, but each subsequent
[5]   ⍝   test will only run if its predecessor returns true.
[6]   ⍝ ← 1 | 0 - whether or not all are true
[7]   ⍝   see ou
[8]    }
     ∇

     ∇ eu←{
[1]        (⊂u⍳⍵)⌷⊢∘⍺⍺/0,⍪u←∪⍵
[2]        (⊂u⍳⍵)⌷⍺⍺¨u←∪⍵
[3]        ⍵ ⍺⍺¨{(⊂⍵⍳⍺)⌷⍺⍺ ⍵}∪⍵
[4]   ⍝ each unique
[5]   ⍝ ⍺⍺ fn to run on each item of ⍵
[6]   ⍝ ⍵ vector
[7]   ⍝ ← equivalent of ⍺⍺¨⍵ ⍝ ***
[8]   ⍝   but having run ⍺⍺ on only a single
[9]   ⍝   instance of each unique value of ⍵
[10]  ⍝   *** and not at all if none.
[11]  ⍝ a fixed left arg can be composed with ⍺⍺ as in:
[12]  ⍝ larg∘fn eu rarg
[13]  ⍝ Phil Last 2016-10-24
[14]   }
     ∇

     ∇ ff←{⍺←⊢
[1]        22::⎕SIGNAL/⌽⎕EN,⎕DM
[2]        ⍺∘⍺⍺{(⎕FUNTIE⊃⍵)⊢⍺⍺ ⍵}{(⎕FSTIE∘0⊃⍵),1↓⍵}⊂if≡⍵
[3]   ⍝ ⎕ffile function
[4]   ⍝ ⍺ [larg] to
[5]   ⍝ ⍺⍺ ⎕ffunction, ⎕FREAD, ⎕FSIZE, ...
[6]   ⍝ ⍵  filename and rest of rarg to ⍺⍺ usually after tie number
[7]   ⍝ thus - vector ⎕FAPPEND¨ff⊂'myfile' - appends items of vector as components
[8]   ⍝ Phil Last ⍝ 2007-06-25 07:53
[9]    }
     ∇

     ∇ fk←{⍺←⊢
[1]        (m d)←'monadic left fork' 'dyadic left fork'
[2]        m≡⍺ m:m ⍺⍺ ⍵(⍵⍵ ⍵)
[3]        ⍺≡m:(⍺⍺ 0⊃⍵)⍵⍵ 1⊃⍵
[4]        ⍺≡d:(⊃⍺⍺/0⊃⍵)⍵⍵ 1⊃⍵
[5]        d ⍺⍺(⍺ ⍵)(⍺ ⍵⍵ ⍵)
[6]   ⍝ fork
[7]   ⍝   f fk g fk h ⍵ ←→ (  f ⍵)g(  h ⍵)
[8]   ⍝ ⍺ f fk g fk h ⍵ ←→ (⍺ f ⍵)g(⍺ h ⍵)
[9]   ⍝ applies g between the results of f and h having
[10]  ⍝   applied each to ⍵ or between ⍺ and ⍵
[11]  ⍝ Phil Last ⍝ 2007-06-23 18:47
[12]   }
     ∇

     ∇ fl←{
[1]        ⊃⍺⍺⍨/⌽(⊂⍺),⍵
[2]   ⍝ for loop (fold left)
[3]   ⍝ a f fl w x y z ←→ ((((a f w)f x)f y)f z)
[4]   ⍝ Phil Last ⍝ 2007-06-23 18:55
[5]    }
     ∇

     ∇ fs←{
[1]        (3=⍴⍵):(0⊃⍵)⍺⍺⊃⍵⍵/1↓⍵
[2]        ⍺⍺(¯2↓⍵),⍵⍵/¯2↑⍵
[3]   ⍝ function sequence
[4]   ⍝ f fs g fs h ... a b c d ... ←→ a f b g c h d ...
[5]   ⍝ nb. all sequenced functions are dyadic;
[6]   ⍝     the derived function is monadic.
[7]   ⍝ Phil Last ⍝ 2007-06-23 16:51
[8]    }
     ∇

     ∇ fv←{
[1]        0::⎕SIGNAL/⌽⎕EN,⎕DM
[2]        ⍺←⊢
[3]        m←⍵≡⍺ ⍵
[4]        (W A)←↓⍵,[-0.1]⍺⊣0
[5]        t←2=⍴W
[6]        m∧t:(⍺⍺ 0⊃W)(⍵⍵ 1⊃W)
[7]        m:(⍺⍺ ¯1↓W),⍵⍵¨⊢/W
[8]        t:((0⊃A)⍺⍺ 0⊃W)((1⊃A)⍵⍵ 1⊃W)
[9]        ((¯1↓A)⍺⍺ ¯1↓W),(⊢/A)⍵⍵¨⊢/W
[10]  ⍝ function vector
[11]  ⍝           f fv g fv h ... x y z ... ←→ (f x)(g y)(h z) ...
[12]  ⍝ a b c ... f fv g fv h ... x y z ... ←→ (a f x)(b g y)(c h z) ...
[13]  ⍝ a b c ... f fv g fv h ... ⊂x        ←→ (a f x)(b g x)(c h x) ...
[14]  ⍝ (⊂a)      f fv g fv h ... x y z ... ←→ (a f x)(a g y)(a h z) ...
[15]  ⍝ requires conformity of ⍺ or ⍵ with number of fns
[16]  ⍝ permits scalar extension of ⍺ xor ⍵ in dyad only
[17]  ⍝ Phil Last ⍝ 2007-06-29 00:00
[18]   }
     ∇

     ∇ hk←{
[1]        ⍺←⍵
[2]        ⍺ ⍺⍺ ⍵⍵ ⍵
[3]   ⍝ hook
[4]   ⍝   ⍺ f hk g ⍵ ←→ ⍺ f g ⍵
[5]   ⍝     f hk g ⍵ ←→ ⍵ f g ⍵
[6]    }
     ∇

     ∇ if←{
[1]        1∊⍵⍵⊣⍵:⍺⍺⊣⍵
[2]        ⍵
[3]   ⍝ consequent if antecedent arg else arg
[4]   ⍝ ⍺⍺    any array or monad on ⍵ to return such
[5]   ⍝ ⍵⍵    boolean singleton or monad on ⍵ to return such
[6]   ⍝ ⍵     array (in domain of either or both of monad ⍺⍺ & ⍵⍵)
[7]   ⍝ ←     array ⍺⍺ or result of ⍺⍺ ⍵ or ⍵ unchanged
[8]   ⍝ Phil Last ⍝ 2008-01-22 12:34
[9]    }
     ∇

     ∇ in←{
[1]        ≥/⍺:⍵                ⍝ no-op
[2]        (¯1=-/⍺):⍵⍵⊣⍵     ⍝ n-1 of n
[3]        (⍺≡0 2):⍺⍺⊣⍵      ⍝ 0 of 2
[4]        (⍺-0 1)⍺⍺ ⍵          ⍝ penultimate?
[5]   ⍝ index list of functions or arrays
[6]   ⍝ i n(f in g in h ... n)⍵
[7]   ⍝ ⍺  index length
[8]   ⍝ ⍺⍺ function/array list
[9]   ⍝ ⍵⍵ function or array
[10]  ⍝ ⍵  arg to functions
[11]  ⍝ ←  result of selected function/array
[12]  ⍝ Phil Last ⍝ 2007-12-23 13:51
[13]   }
     ∇

     ∇ ir←{
[1]        ⊃⍺⍺⌿⊂⍤¯1⊢⍵
[2]   ⍝ Iverson's reduction
[3]   ⍝ ⍺⍺ fn to insert
[4]   ⍝ ⍵  array between whose major cells to apply ⍺⍺
[5]    }
     ∇

     ∇ it←{
[1]        ⍺←⊢
[2]        ⍺ ⍵⍵⍣(⍬⍴⍺⍺⊣⍵)⊢⍵
[3]   ⍝ r ←   n iterate{f}w
[4]   ⍝ r ← a{n}iterate{f}w
[5]   ⍝ ⍺  [larg to ⍵⍵]
[6]   ⍝ ⍺⍺ no. of iterations or fn to return it
[7]   ⍝ ⍵⍵ fn to run (⍺⍺⊣⍵) times on ⍵ and successors
[8]   ⍝ ⍵  arg to first if any iteration
[9]    }
     ∇

     ∇ ix←{
[1]        w←⍵
[2]        i←⍺⍺⊣⍳⍴w
[3]        ⍺←⊢
[4]        1≡⍺ 1:w[i]
[5]        {w}w[i]←⍺
[6]   
[7]   ⍝ ⍺  source data if it is to be replaced
[8]   ⍝ ⍺⍺ array of ⍵-indices whence result to be drawn or function to generate such
[9]   ⍝    or
[10]  ⍝    array of ⍵-indices whither ⍺ to be assigned or function to generate such
[11]  ⍝ ⍵  target array
[12]  ⍝ ←  monad: subarray of ⍵ selected by ⍺⍺⊣⍵
[13]  ⍝    dyad:  ⍵ with items selected by ⍺⍺⊣⍵ replaced by ⍺
[14]   }
     ∇

     ∇ jn←{⍺←⍺
[1]        s←'internal left argument'
[2]        ⍺≢s:s ⍺⍺ ⍺(⍵⍵ ⍵)
[3]        s d←⍵
[4]        (⍺⍺ s)⍵⍵ d
[5]   ⍝ janus looking both ways
[6]   ⍝ a f jn g jn h w ←→ (f a)g(h w)
[7]   ⍝               ←→ a ((f⊣) g ⊢∘h) w
[8]   ⍝ first:  ⍺ ←→ a ⋄ ⍺⍺ ←→ f jn g ⋄ ⍵⍵ ←→ h ⋄ ⍵ ←→ w
[9]   ⍝ second: ⍺ ←→ d ⋄ ⍺⍺ ←→ f      ⋄ ⍵⍵ ←→ g ⋄ ⍵ ←→ a(h w)
[10]   }
     ∇

     ∇ ky←{⍺←⊢
[1]        0::⎕SIGNAL/⌽⎕EN,⎕DM
[2]        ⍵≡⍺ ⍵:⍵ ∇⍳⍬⍴⍴⍵
[3]        u←∪i←⍳⍨⊂[1↓⍳⍴⍴k]⊢k←⍺
[4]        f←⍺⍺
[5]        ↑u{(⍺⌷k)f ⍵}¨(↓u∘.=i)⌿¨⊂⍵
[6]   
[7]   ⍝ key
[8]   ⍝ ⍺ ⍺⍺ ky ⍵
[9]   ⍝   ⍺⍺ ky ⍵ ←→ ⍵ ⍺⍺ ky ⍳⍬⍴⍴ ⍵
[10]  ⍝ d: (⍬⍴⍴⍺)←→(⍬⍴⍴⍵)
[11]  ⍝   ⍺ keys array (major cells)
[12]  ⍝   ⍵ corresponding data array (in first dimension)
[13]  ⍝   ⍺⍺ dyad applied between each unique key and the
[14]  ⍝       corresponding major cells of the data as - key ⍺⍺ cells
[15]  ⍝ m:
[16]  ⍝   ⍺⍺ applied beteen each unique major cell of ⍵ and the corresponding
[17]  ⍝       subset of ⍳⍬⍴⍴⍵
[18]  ⍝ ← assembled result of applications of ⍺⍺
[19]  ⍝ Phil Last ⍝ 2008-05-29 10:39
[20]   }
     ∇

     ∇ lg←{
[1]        ⊃(0 1 2 3=⊂⍺+⍺+⍵)∨.∧{
[2]            ⊂[1+⍳⍴⍴⍵]2 2 2 2⊤⍵
[3]        }⍺⍺⊣⍬
[4]   ⍝ Logic - p{i}lg q
[5]   ⍝ ⍺ & ⍵ - p & q are scalar conformable boolean arrays, any rank any depth.
[6]   ⍝ ⍺⍺    - simple integer array or constant function to return i, scalar
[7]   ⍝         conformable with p & q, whose items are zero indices into
[8]   ⍝         conceptual logical scalar function vector ...
[9]   ⍝   0   1 2    3    4    5    6 7 8 9   10   11   12   13 14 15
[10]  ⍝ (0∧=) ∧ > (⊣∧⊢=⊢) < (⊢∧⊣=⊣) ≠ ∨ ⍱ = (⊢<⊣=⊣) ≥ (⊣<⊢=⊢) ≤ ⍲ (1∨=)
[11]  ⍝ {i}lg is therefore a (⍴i) shaped logical function array
[12]  ⍝  0  3 5  10   12  15  are scalar eqivalents of
[13]  ⍝ {0} ⊣ ⊢ (~⊢) (~⊣) {1}
[14]  ⍝ Phil Last ⍝ 2007-06-25 15:00
[15]   }
     ∇

     ∇ lm←{
[1]        ⍵ ⍺⍺{⍺≡⍵:⍵ ⋄ ⍵ ⍺⍺ ∇∇ ⍺⍺ ⍵ ⋄ ⍵:⍵≡⍺}⍺⍺ ⍵
[2]   ⍝ limit ←→ ⍣≡
[3]    }
     ∇

     ∇ lt←{
[1]        A B C D←112358314594370 774156178538190 998752796516730 336954932572910
[2]        ⍺←A
[3]        ⍺≡A:B ∇ ⍵
[4]        ⍺≡B:(⊂⍣(~B∊z)⊢z←⍺⍺ ⍵),B,⊂⍵⍵ ⍵
[5]   
[6]        ⍺≡D:(⊂⍣(~D∊z)⊢z←D ⍺⍺ ⍺ ⍵),D,⊂⊃⍵⍵/⍵
[7]        D ∇ ⍺ ⍵
[8]    }
     ∇

     ∇ mf←{
[1]        ⍺←⊢
[2]        (⍺ ⍺⍺ ⍵)≡⍺ ⍵⍵ ⍵
[3]   ⍝ match fn results
[4]   ⍝ Phil Last ⍝ 2007-12-21 16:56
[5]    }
     ∇

     ∇ mg←{
[1]        {W}W[⍺⍺⊣⍳⍴W←⍵]←⍺
[2]   ⍝ merge
[3]   ⍝ ⍺  source data
[4]   ⍝ ⍺⍺ a function to select from index array of (⍵) - (⍳⍴⍵)
[5]   ⍝    or an array being a prior selection of those indices
[6]   ⍝ ⍵  target array
[7]   ⍝ ←  (⍵) with data from (⍺) merged at positions specified by (⍺⍺)
[8]   ⍝    {W}W[⍺⍺⊣{⊂⍬}⍣(0∊⍴⍴⍵)⍳⍴W←⍵]←⍺ ⍝ would permit scalar ⍵
[9]   ⍝ Phil Last ⍝ 2008-01-23 11:06
[10]   }
     ∇

     ∇ mo←{
[1]        ⍺⍺ ⍵
[2]   ⍝ monadic - ignore ⍺
[3]    }
     ∇

     ∇ nf←{
[1]        ⍺←⊢
[2]        ⍺∘⍺⍺{(⎕NUNTIE⊃⍵)⊢⍺⍺ ⍵}(⎕NTIE∘0⊃⍵),1↓⍵
[3]   ⍝ ⎕nfile function
[4]   ⍝ ⍺ [larg] to
[5]   ⍝ ⍺⍺ ⎕Nfunction, ⎕NREAD, ⎕NSIZE, ...
[6]   ⍝ ⍵  filename and rest of rarg to ⍺⍺ usually after tie number
[7]   ⍝ thus - ⎕NREAD nf 'myfile' 80 100 0 - reads first 100 bytes
[8]   ⍝ Phil Last ⍝ 2007-06-25 07:53
[9]    }
     ∇

     ∇ nl←{
[1]        ⍺←⊢
[2]        (⍕⍺⍺),⍤1⊢'.',⍺ ⍺⍺.⎕NL ⍵
[3]   ⍝    (⍕⍺⍺),rk{1}'.',⍺ ⍺⍺.⎕NL ⍵
[4]   ⍝ name list
[5]   ⍝ ⍺ [chars]
[6]   ⍝ ⍺⍺ space
[7]   ⍝ ⍵ name class(es)
[8]   ⍝ ← fully qualified namelist
[9]   ⍝   ⍺(⍺⍺ nl)⍵ ←~→ ⍺ ⍺⍺.⎕NL ⍵
[10]  ⍝     ⍺⍺ nl ⍵ ←~→   ⍺⍺.⎕NL ⍵
[11]  ⍝ Phil Last 2017-05-04 22.33
[12]   }
     ∇

     ∇ nr←{
[1]        ⍺←⍵
[2]        6::⍺{⍵:⍺}1∊(2 4⍴' ⊢∧   ')⍷↑⎕DM
[3]        ⊢⍺⍺ ⍵
[4]   ⍝ no result
[5]   ⍝ ⍺  the default result required from ⍺⍺ if none - ⍵ if not supplied
[6]   ⍝ ⍺⍺ any function - if dyadic bind its left arg as - larg∘fn
[7]   ⍝ ⍵  any array
[8]   ⍝ ←  result of (⍺⍺ ⍵) or (⍺) if none or (⍵) if none
[9]   ⍝ Phil Last ⍝ 2008-03-06 12:30
[10]   }
     ∇

     ∇ nv←{⍺←⊢
[1]        ⍵.(⍺⍺{⍵,⍪⍺⍺¨1↓⍎¨'0',⍵}⍺∩⍨⎕NL-2.1)
[2]   ⍝ namespace vars - all or those mentioned in ⍺ if supplied
[3]   ⍝ ⍵  space
[4]   ⍝ ←  2-col table - names values
[5]   ⍝                  ...
[6]   ⍝ ⍺⍺ function to run on each value
[7]   ⍝      ⍴nv dx'oneVec twoD scalar'((⍳1)(⍳2 3)('A'))
[8]   ⍝ oneVec  1
[9]   ⍝ scalar
[10]  ⍝ twoD    2 3
[11]   }
     ∇

     ∇ on←{
[1]        ⍺←⊢
[2]        ⍺⍺ ⍺ ⍵⍵ ⍵
[3]   ⍝ atop
[4]   ⍝ ~at= ←→ ≠
[5]   ⍝ ~at∨ ←→ ⍱
[6]   ⍝ ⍺ f on g ⍵ ←→ f ⍺ g ⍵
[7]   ⍝   f on g ⍵ ←→ f∘g ⍵
[8]    }
     ∇

     ∇ or←{
[1]        ~1∊⍺:⍵         ⍝ none
[2]        </⍺:⍵⍵⊣⍵    ⍝ only last
[3]        2=⍴⍺:⍺⍺⊣⍵   ⍝ first of 2
[4]        (¯1↓⍺)⍺⍺ ⍵     ⍝ penultimate?
[5]   ⍝ select from list of functions
[6]   ⍝ i j k ... f or g or h ... w
[7]   ⍝ ↑ ←→ ↓
[8]   ⍝ :Select 1
[9]   ⍝    :Case i ⋄ f w
[10]  ⍝    :Case j ⋄ g w
[11]  ⍝    :Case k ⋄ h w
[12]  ⍝     ...
[13]  ⍝    :Else ⋄ w
[14]  ⍝ :End
[15]  ⍝ Phil Last ⍝ 2007-06-22 01:30
[16]   }
     ∇

     ∇ ou←{ ⍝ or
[1]        ⍺⍺⊣⍵:1 ⋄ ⍵⍵ ⍵
[2]   ⍝ f0 ou f1 ou f2 ou ... ⍵
[3]   ⍝ ⍵ any array in domain of f0
[4]   ⍝   f0 f1 f2 &c. are monadic tests on ⍵, but each subsequent
[5]   ⍝   test will only run if its predecessor returns false.
[6]   ⍝ ← 1 | 0 - whether or not any is true
[7]   ⍝   see et
[8]    }
     ∇

     ∇ pm←{⍺←⊢
[1]        z←⎕PROFILE'clear'
[2]        z←⎕PROFILE'start'
[3]        r←⍺ ⍺⍺⍣⍵⍵⊢⍵
[4]        z←⎕PROFILE'stop' ⋄ e←⍬⍴⎕LC
[5]        p←e↓⍉↑(1+⍳5)⎕PROFILE'data'
[6]        p[;3]←100×(⊢÷+/)p[;3]
[7]        r{⍺ ⍵}p[⍒p[;3];]
[8]   ⍝ profile monitor
[9]   ⍝ ⍺     [larg]
[10]  ⍝ ⍺⍺    fn
[11]  ⍝ ⍵⍵    rop to ⍣ (fn or int)
[12]  ⍝ ⍵     rarg
[13]  ⍝ ←     res prof
[14]  ⍝ res   result of: ⍺ ⍺⍺⍣⍵⍵⊢⍵
[15]  ⍝ prof  ⎕profile result
[16]   }
     ∇

     ∇ po←{
[1]        ⍺←≡
[2]        (⍺⍺⍣⍺)⍵
[3]   ⍝ hence is how to do it without ⍣
[4]        ⍺←⊢
[5]        1≢⍺ 1:⊃⊢∘⍺⍺/(⍳⍺),⊂⍵                  ⍝ ⍺ is iterations
[6]        ⍵ ⍺⍺{⍺≡⍵:⍵ ⋄ ⍵ ⍺⍺ ∇∇ ⍺⍺ ⍵ ⋄ ⍵:⍵≡⍺}⍺⍺ ⍵ ⍝ 'til no change
[7]   ⍝ power
[8]   ⍝ Phil Last ⍝ 2008-01-07 09:18
[9]    }
     ∇

     ∇ pq←{
[1]        ⊃(|⍵ ⍺ 0-⊂⍺×⍵){⊃|⍺-⊃⍺⍺+.×⍺≠⍵}/1 1 0 0⊂,∘.⍺⍺⍨0 1
[2]   ⍝ probability
[3]   ⍝ If L is a logical function and p & q are respectively
[4]   ⍝ the probabilities of the truths of propositions P & Q
[5]   ⍝ p L pq q is the probability of the truth of proposition P L Q
[6]   ⍝ Phil Last ⍝ 2007-06-22 22:57
[7]    }
     ∇

     ∇ pt←{
[1]        (⍺⍺⊣⍵){(⍺/2</0,⍺)⊂⍺/⍵}⍵
[2]   ⍝ partition
[3]   ⍝ ⍺⍺ boolean string or fn to return such given ⍵
[4]   ⍝ ⍵  string
[5]   ⍝ ← ⍵ partitioned each partition being ⍵ corresponding
[6]   ⍝   to a contiguous string of 1s in ⍺⍺⊣⍵
[7]   ⍝ Phil Last ⍝ 2008-02-12 07:51
[8]    }
     ∇

     ∇ rk←{
[1]        mlr←⌽3⍴⌽⍵⍵,⍬
[2]        m←(f←⍺⍺)/0
[3]        ⍺←m←(f←⊢∘⍺⍺)/1
[4]        l r←-1↓r⌊|l+r×0>l←(mlr⌊r←3⍴(⍴⍴⍵),⍴⍴⍺)[⍒m×⍳3]
[5]        5::⎕SIGNAL/⌽⎕EN,⎕DM
[6]        {↑⍵⍴¨⍨↓1+⌽↑-1-⌽∘⍴¨⍵}(⊂[l↑⍳⍴⍴⍺]⍺)f¨⊂[r↑⍳⍴⍴⍵]⍵
[7]   ⍝ rank
[8]   ⍝   f rk{m l r}
[9]   ⍝ applies f to m-cells of ⍵ or between l-cells of ⍺ and r-cells of ⍵
[10]  ⍝ Phil Last ⍝ 2007-06-22 22:57
[11]   }
     ∇

     ∇ rx←{
[1]        ⍺←⍵ ⋄ (⍺⍺ ⍺)⍵⍵ ⍵
[2]   ⍝ reflex
[3]   ⍝ ⍺ [array]
[4]   ⍝ ⍵ array
[5]   ⍝ ← apply left monad to [⍺] else ⍵ and
[6]   ⍝   right dyad twixt left result and ⍵
[7]    }
     ∇

     ∇ ss←{
[1]        (⍴,⍵)↑1↓⌽⊃⍺⍺{⍬⍴⍵:⍵ ⋄ ⍺⍺ ⍺:1,⍵ ⋄ 0,⍵}/⌽0,⍵
[2]   ⍝ stop scan
[3]   ⍝    <\⍺⍺¨⍵ but ⍺⍺ runs only until a one is encountered
[4]   ⍝ ⍺⍺ a potentially expensive boolean returning function
[5]   ⍝ ⍵  a vector whose items are all valid arguments to ⍺⍺
[6]   ⍝ ←  boolean vector length of ⍵ having one or zero ones
[7]    }
     ∇

     ∇ st←{
[1]        0 ⍺⍺{
[2]            ⍬⍴⍺:⍺
[3]            ⍬⍴r←⍺⍺ ⍵:r
[4]            ⊃∇⍨/(⍵⍵ ⍵),0
[5]        }⍵⍵ ⍵
[6]   ⍝ search tree - return on first hit or exhaustion
[7]   ⍝ ⍺⍺ test
[8]   ⍝    ⍵ node (namespace, folder ...
[9]   ⍝    ← boolean, other data
[10]  ⍝ ⍵⍵ subtree  - needs to check for recursion
[11]  ⍝    ⍵ node
[12]  ⍝    ← list of nodes in ⍵
[13]  ⍝ ⍵  tree
[14]  ⍝ ←  as of last search
[15]   }
     ∇

     ∇ tf←{
[1]        ⍺←⊢
[2]        (1=⍺⊣0):⍺⍺⊣⍵ ⍝ antecedent
[3]        (0=⍺⊣1):⍵⍵⊣⍵ ⍝ consequent
[4]        (1 ⍺⍺ ⍵):0 ⍺⍺ ⍵    ⍝ antecedent then consequent
[5]        ⍵⍵⊣⍵            ⍝ else alternative
[6]   ⍝ true false
[7]   ⍝   antecedent tf consequent tf alternative
[8]   ⍝ applies antecedent followed by consequent or alternative to ⍵
[9]   ⍝   antecedent, consequent and alternative are arrays or monads
[10]  ⍝ Phil Last ⍝ 2008-01-22 07:53
[11]   }
     ∇

     ∇ ti←{⍺←⊢
[1]        op←{⍺←⊢
[2]            0.001×÷/2⍴⌽1⊢∘(⊢∘(⍺∘⍺⍺)∘⍵){⍺,⊃∇/⍺{(1000<⍵)↓(2×⍺)⍵}⍺⍺{⍬⍴2↓⎕AI-(⍺⍺/⍳1+⍵)⊢⎕AI}⍺}1
[3]        }
[4]        (⍺ ⍺⍺ op ⍵)-⍺⊢op ⍵
[5]   ⍝ time function
[6]   ⍝ ⍺ larg to ⍺⍺
[7]   ⍝ ⍺⍺ fn to be timed
[8]   ⍝ ⍵ rarg to ⍺⍺
[9]   ⍝ ← seconds per execution averaged over at least one second
[10]  ⍝ Phil Last ⍝ 2007-12-21 17:01
[11]   }
     ∇

     ∇ tk←{⍺←⊢
[1]        ticks←⎕AI[2]'----+----|'{go ten←⍺ ⋄ prev←⍵
[2]            now←⌊0.5+(⎕AI[2]-go)÷1000 ⋄ ⍞←prev↓now⍴ten
[3]            ⍺ ∇ now⊣⎕DL 1}&0
[4]        (⎕TKILL ticks)⊢⍺ ⍺⍺ ⍵
[5]   ⍝ tick
[6]   ⍝ run and return {⍺} ⍺⍺ ⍵ while displaying 1 second ticks
[7]    }
     ∇

     ∇ ts←{⍺←⊢
[1]        ⊃'s'mn ⍺ ⍺⍺ ti ⍵
[2]   ⍝
[3]    }
     ∇

     ∇ ud←{⍺←⎕SIGNAL 6
[1]        (⍵⍵ ⍺)⍺⍺ ⍵⍵ ⍵
[2]   ⍝ under
[3]   ⍝ Phil Last 2017-12-04 08.28
[4]    }
     ∇

     ∇ un←{
[1]        ⍺⍺{⍵⍵ ⍵:⍵ ⋄ ∇ ⍺⍺ ⍵}⍵⍵ ⍺⍺ ⍵
[2]        ∇{⊢∘⍺⍺/(1~⍵⍵ ⍵),⊂⍵}⍵⍵ ⍺⍺ ⍵
[3]        ⍺⍺⍣(⊢∘⍵⍵⍨)⍵
[4]        ⍺⍺⍣(⍵⍵{⍺⍺ ⍺})⍵
[5]   ⍝ until
[6]   ⍝ ⍺⍺ monad on ⍵ and successors displaying closure property.
[7]   ⍝ ⍵⍵ boolean scalar returning monad on successors of ⍵
[8]   ⍝    whose truth terminates iteration.
[9]   ⍝ ⍵  array in domain of ⍺⍺
[10]  ⍝ ←  first result of ⍺⍺ ⍺⍺ ... ⍵ to satisfy ⍵⍵
[11]  ⍝ Phil Last ⍝ 2008-12-02 10:27
[12]   }
     ∇

     ∇ ut←{⍺←⊢ ⋄ f←⍺⍺ ⋄ t←⍵⍵
[1]        ⍵≡⍺ ⍵:f⍣(t⊣)⍵
[2]        ⍺{ ⍝ keep recursion local
[3]            (⍺-1)∘∇⍣((⍺>1)>t z)⊢z←f ⍵
[4]        }⍵
[5]   ⍝ until
[6]   ⍝ ⍺     [max]
[7]   ⍝ ⍺⍺    monadic fn on arg - may be composed: (const∘function)
[8]   ⍝ ⍵⍵    monadic test on arg or subsequent results
[9]   ⍝ ⍵     arg
[10]  ⍝       apply fn [up to max times] until test result
[11]  ⍝ ←     last application of fn
[12]  ⍝ e.g.
[13]  ⍝+-----------------------+--------------------------+
[14]  ⍝|       +∘1 ut (≥∘5) 0  |       10 +∘1 ut (≥∘5) 0  |
[15]  ⍝| 5                     | 5                        |
[16]  ⍝+-----------------------+--------------------------+
[17]  ⍝|       +∘1 ut (≥∘15) 0 |       10 +∘1 ut (≥∘15) 0 |
[18]  ⍝| 15                    | 10                       |
[19]  ⍝+-----------------------+--------------------------+
[20]   }
     ∇

     ∇ wh←{
[1]        f←⍺⍺ ⋄ g←⍵⍵
[2]        (⍴⍵)⍴{⍵{⍵⊖⍺,[-0.1]⍵\f ⍵/⍺},g⊣⍵},⍵
[3]   ⍝ where
[4]   ⍝ ⍺⍺  fn applied to vector of items
[5]   ⍝     selected from (⍵) where (⍵⍵)(⍵) true
[6]   ⍝ ⍵⍵  (⍴⍵)⍴boolean or fn applied to (⍵) to return such
[7]   ⍝ ⍵   array
[8]   ⍝ ←   (⍵) changed by (⍺⍺) where (⍵⍵)⍵
[9]   ⍝ ⍺⍺ & ⍵⍵ expected to be scalar functions.
[10]  ⍝ otherwise use (⍺⍺¨) (⍵⍵¨) as in:
[11]  ⍝     (⍺⍺¨)wh(⍵⍵¨)⍵
[12]  ⍝ nb. A fixed left arg can be composed with ⍺⍺ as:
[13]  ⍝     larg∘⍺⍺ wh ⍵⍵ rarg
[14]  ⍝ Phil Last ⍝ 2008-03-11 18:15
[15]   }
     ∇

     ∇ wl←{
[1]        ⍵⍵ ⍵:∇ ⍺⍺ ⍵
[2]        ⍵
[3]        ⍺⍺⍣(⊢∘~∘⍵⍵⍨)⍣(⍵⍵ ⍵)⊢⍵
[4]        ⍺⍺⍣(⍵⍵{~⍺⍺ ⍺})⍣(⍵⍵ ⍵)⊢⍵
[5]        ⊢∘∇∘⍺⍺/(1∩⍵⍵ ⍵),⊂⍵
[6]   ⍝ while
[7]   ⍝ ⍺⍺ fn to run repeatedly while
[8]   ⍝ ⍵⍵ test on ⍵ is true
[9]   ⍝ ←  ⍵ or ⍺⍺ ⍵ or ⍺⍺ ⍺⍺ ... ⍵
[10]   }
     ∇

     ∇ wt←{
[1]        sofar inc←0 0.1
[2]        wait←⊃⍵⍵,1
[3]        rslt←this←⎕NS''
[4]        tid←⍺⍺{6::
[5]            rslt∘←⍺⍺ ⍵
[6]        }&⍵
[7]        {(tid∊⎕TNUMS)≤wait≤sofar:0
[8]            ∇ sofar+←⎕DL inc
[9]        }0:
[10]       tid←⎕TKILL tid
[11]       rslt≢this:rslt
[12]       ⍺←⊢
[13]       1≢⍺ 1:⍺
[14]  ⍝ wait
[15]  ⍝ ⍺  dflt result if supplied
[16]  ⍝ ⍺⍺ function - monad or (larg∘dyad)
[17]  ⍝ ⍵⍵ seconds for (⍺⍺) to finish - number or {fn} to return such
[18]  ⍝ ⍵  rarg to (⍺⍺)
[19]  ⍝ ←  If (⍺⍺) returns a result then this returns it.
[20]  ⍝    Otherwise if (⍺) is supplied this returns that.
[21]  ⍝    Otherwise this returns nothing.
[22]  ⍝ Phil Last ⍝ 2007-06-23 18:50
[23]   }
     ∇

     ∇ wt0←{
[1]        ns←⎕NS''
[2]        ns.(sofar inc)←0 0.1
[3]        ns.wait←⊃⍵⍵,1
[4]        ns.(rslt this)←⎕NS''
[5]        ns.tid←⍺⍺{6::
[6]            ⍵⍵.rslt∘←⍺⍺ ⍵
[7]        }ns&⍵
[8]        ns∘{(⍺.tid∊⎕TNUMS)≤⍺.wait≤⍺.sofar:0
[9]            ∇ ⍺.sofar+←⎕DL ⍺.inc
[10]       }0:
[11]       ns.tid←⎕TKILL ns.tid
[12]       ns.rslt≢ns.this:ns.rslt
[13]       ⍺←⊢
[14]       1≢⍺ 1:⍺
[15]  ⍝ wait
[16]  ⍝ ⍺  dflt result if supplied
[17]  ⍝ ⍺⍺ function - monad or (larg∘dyad)
[18]  ⍝ ⍵⍵ seconds for (⍺⍺) to finish - number or {fn} to return such
[19]  ⍝ ⍵  rarg to (⍺⍺)
[20]  ⍝ ←  If (⍺⍺) returns a result then this returns it.
[21]  ⍝    Otherwise if (⍺) is supplied this returns that.
[22]  ⍝    Otherwise this returns nothing.
[23]  ⍝ Phil Last ⍝ 2007-06-23 18:50
[24]   }
     ∇

     ∇ xa←{
[1]        ⍺←⊢
[2]        0::⍺ ⍺⍺⊣⍵
[3]        1:⍺ ⍵⍵ ⍵
[4]   ⍝ execute alternative
[5]   ⍝ if error in ⍵⍵ then ⍺⍺
[6]   ⍝ if ⍺ elided then functions called as monads and ⍺⍺ may be an array
[7]    }
     ∇

     ∇ æ←{⍺←⍺
[1]        s←'internal left argument'
[2]        ⍺≢s:s ⍺⍺ ⍺(⍵⍵ ⍵)
[3]        s d←⍵
[4]        (⍺⍺ s)⍵⍵ d
[5]   ⍝ a f æ g æ h w ←→ (f a)g(h w)
[6]   ⍝               ←→ a ((f⊣) g ⊢∘h) w
[7]   ⍝ first:  ⍺ ←→ a ⋄ ⍺⍺ ←→ f æ g ⋄ ⍵⍵ ←→ h ⋄ ⍵ ←→ w
[8]   ⍝ second: ⍺ ←→ d ⋄ ⍺⍺ ←→ f      ⋄ ⍵⍵ ←→ g ⋄ ⍵ ←→ a(h w)
[9]    }
     ∇