@echo off
REM ------------------------------------------------------------
REM          Howto build the W3C CSS Validator on Win32         
REM ------------------------------------------------------------
REM This batch file assumes that you have installed
REM
REM   cvs           (http://www.cvshome.org)               --> %PATH%
REM   zip           (http://www.info-zip.org/pub/infozip/) --> %PATH%
REM   Java SDK      (http://java.sun.com/)                 --> c:\java
REM   Apache Ant    (http://ant.apache.org/)               --> c:\winapp\ant\
REM   Apache Tomcat (http://jakarta.apache.org/tomcat/)    --> c:\winapp\tomcat\
REM   (only the servlet-api.jar is required from Tomcat)
REM
REM and successfully logged into W3C anonymous CVS; to
REM do so execute the following command from your shell
REM
REM   cvs -d:pserver:anonymous@dev.w3.org:/sources/public login
REM
REM and type "anonymous" at the password prompt.
REM
REM It will retrieve the latest W3C CSS Validator sources and
REM some dependencies from dev.w3.org to the current working
REM directory, generate a custom Apache Ant build script, call
REM Ant to build the sources, call zip to compress the compiled
REM sources into a .zip file, and delete all remaining files.
REM ------------------------------------------------------------
REM        Bjoern Hoehrmann -- http://bjoern.hoehrmann.de       
REM ------------------------------------------------------------
cvs -z9 -d:pserver:anonymous@dev.w3.org:/sources/public export -r HEAD 2002/css-validator
mkdir 2002\css-validator\org\w3c\www
mkdir 2002\css-validator\org\w3c\www\mime
cvs -z9 -d:pserver:anonymous@dev.w3.org:/sources/public co -p java/classes/org/w3c/www/mime/MimeType.java > 2002\css-validator\org\w3c\www\mime\MimeType.java
cvs -z9 -d:pserver:anonymous@dev.w3.org:/sources/public co -p java/classes/org/w3c/www/mime/MimeTypeFormatException.java > 2002\css-validator\org\w3c\www\mime\MimeTypeFormatException.java
cd 2002\css-validator
echo ^<project default="build" name="CSS validator"^>                                       > mybuildfile.xml
echo ^<target name="build"^>                                                               >> mybuildfile.xml
echo ^<mkdir dir="../../css-validator-release" /^>                                         >> mybuildfile.xml
echo ^<javac destdir="../../css-validator-release" srcdir="./org/w3c:html" debug="yes" /^> >> mybuildfile.xml
echo ^<copy todir="../../css-validator-release"^>                                          >> mybuildfile.xml
echo ^<fileset dir="./"^>^<exclude name="**/*.java" /^>                                    >> mybuildfile.xml
echo ^<exclude name="mybuildfile.xml" /^>^</fileset^>                                      >> mybuildfile.xml
echo ^</copy^>                                                                             >> mybuildfile.xml
echo ^</target^>                                                                           >> mybuildfile.xml
echo ^</project^>                                                                          >> mybuildfile.xml
set _classpath=%classpath%
set classpath=%classpath%;c:\java\lib\tools.jar;c:\winapp\tomcat\common\lib\servlet-api.jar
call c:\winapp\ant\bin\ant -noinput -f mybuildfile.xml
set classpath=%_classpath%
set _classpath=
del mybuildfile.xml
cd ..\..
cd css-validator-release
zip -9 -r -T -m ..\validator-snapshot.zip .
cd ..
rd css-validator-release
rd /s /q 2002
:end