Window Object 1.0

// should this interface be called something else - Global, DOMWindow, DOMGlobal?
// should specify that for ECMAScript execution this provides the global scope
// based on Mozilla and Safari implementations, Win IE docs, Web Apps 1.0 draft
// (some also in SVG Tiny 1.2 draft)
interface Window : views::AbstractView {
    // AbstractView has a document attribute of type DocumentView, should we drop the
    // charade and admit it is a Document?

    // self-reference
    readonly attribute Window window;

    // self-reference - why both? because both are used
    readonly attribute Window self;
};

interface DocumentWindow : views::DocumentView {
// the defaultView must be the Window object
};

interface WindowLocation {
    // Location object representing the current location
    // assigning this has special behavior in ECMAScript, but it is otherwise 
    // read only. specifically, in ES a string URI can be assigned to location, 
    // having the same effect as location.assign(URI)
    readonly attribute Location location;
};

interface DocumentLocation {
    // must be same object as window.location
    // same special JS assignment as window.location
    readonly attribute Location location;
};

interface Location {
    attribute DOMString href;
		
    // pieces of the URI, per the generic URI syntax
    attribute DOMString hash; // (fragment)
    attribute DOMString host; // hostname:port if port specified,
    attribute DOMString hostname; // just the hostname, no port
    attribute DOMString pathname;
    attribute DOMString port;
    attribute DOMString protocol; // scheme
    attribute DOMString search;  // query

    void assign(in DOMString url); // go to the requested URL
    // does it make sense to spec reload and replace without specifying 
    // history behavior at all?
    void replace(in DOMString url);
    void reload();

    // same value as href; not all implementations have this explicitly 
    // but toString is always available in ECMAScript, and probably this 
    // should be explicit for the sake of Java. Or we could skip it since
    // it matches href.
    DOMString toString();
};

interface WindowEmbedding {
    // name attribute of referencing frame/iframe/object, or name passed to 
    // window.open, does it make sense to spec this without being html-specific 
    // or defining open?
    attribute DOMString name;

    // global object of containing document
    readonly attribute Window parent;

    // global object of outermost containing document
    readonly attribute Window top;

    // referencing <html:frame>, <html:iframe>, <html:object>, <svg:foreignObject>, 
    // <svg:animation> or other embedding point, or null if none
    readonly attribute core::Element frameElement;
};

// must be on an object that also implements core::Element
interface EmbeddingElement {
    readonly attribute core::Document contentDocument;
    readonly attribute Window contentWindow;
};

interface WindowTimers {
    // should timers allow more than long, maybe a floating point type? 
    // don't think anyone's timers have more precision

    // one-shot timer
    long setTimeout(in TimerListener listener, in long milliseconds);
    void clearTimeout(in long timerID);

    // repeating timer
    long setInterval(in TimerListener listener, in long milliseconds);
    void clearInterval(in long timerID);
};

// behavior is always special in ECMAScript, this is defined only for the benefit
// of other languages
interface TimerListener {
    // what to put here?
};