W3C home > Mailing lists > Public > public-i18n-core@w3.org > January to March 2011

Re: Minor comments on Widgets

From: Marcos Caceres <marcosc@opera.com>
Date: Thu, 17 Mar 2011 14:14:38 +0100
Message-ID: <4D82093E.4010409@opera.com>
To: Arthur Barstow <art.barstow@nokia.com>
CC: "Phillips, Addison" <addison@lab126.com>, "public-webapps@w3.org" <public-webapps@w3.org>, "public-i18n-core@w3.org" <public-i18n-core@w3.org>
On 3/17/11 1:14 PM, Arthur Barstow wrote:
> [Ooops; Sent before read ... ]
>
> Marcos - Addison's comments were submitted during the comment period of
> a proposal to publish a new LCWD of this spec. I think that publication
> should be blocked until there is consensus on how to address the comments.

I have updated the spec with the new rule:

Zip-rel-path   = [locale-folder] *folder-name file-name /
                  [locale-folder] 1*folder-name
locale-folder  = %x6C %x6F %x63 %x61 %x6C %x65 %x73
                  "/" lang-tag "/"
folder-name    = file-name "/"
file-name      = 1*allowed-char
allowed-char   = safe-char / zip-UTF8-char
zip-UTF8-char  = UTF8-2 / UTF8-3 / UTF8-4
safe-char      = ALPHA  / DIGIT / SP  / "$" / "%" /
                  "'"    / "-"   / "_" / "@" / "~" /
                  "("    / ")"   / "&" / "+" / "," /
                  "="    / "["   / "]" / "."
UTF8-2         = %xC2-DF UTF8-tail
UTF8-3         = %xE0 %xA0-BF UTF8-tail / %xE1-EC 2( UTF8-tail ) /
                  %xED %x80-9F UTF8-tail / %xEE-EF 2( UTF8-tail )
UTF8-4         = %xF0 %x90-BF 2( UTF8-tail ) / %xF1-F3 3( UTF8-tail ) /
                  %xF4 %x80-8F 2( UTF8-tail )
UTF8-tail      = %x80-BF
lang-tag       = primary-subtag *( "-" subtag )
primary-subtag = 1*8low-alpha
subtag         = 1*8(alphanum)
alphanum       = low-alpha  / DIGIT
low-alpha      = %x61-7a


And added to the Changes since last publication:

"We fixed the ABNF of zip-rel-path to disallow, and also disallowed 
constructions such as "en-*-foo". This was done by making the 
language-tag rule similar to obs-language-tag as defined in [BCP47], but 
restricting productions to lower case. We also fixed a typo in the ABNF 
for low-alpha (changed %x61-71 to %x61-7a so it actually covers the 
lower case ASCII characters)."
Received on Thursday, 17 March 2011 13:16:57 GMT

This archive was generated by hypermail 2.2.0+W3C-0.50 : Thursday, 17 March 2011 13:16:58 GMT