W3C home > Mailing lists > Public > ietf-http-wg@w3.org > October to December 2006

RFC2616 erratum "languagetag"

From: Julian Reschke <julian.reschke@gmx.de>
Date: Sat, 14 Oct 2006 14:13:41 +0200
Message-ID: <4530D475.4080200@gmx.de>
To: HTTP Working Group <ietf-http-wg@w3.org>

Hi,

<http://skrb.org/ietf/http_errata.html#languagetag> recommends to update 
RFC2616 to refer to RFC3066. In the meantime, RFC3066 has been obsoleted 
by RFC4646, and the original grammar production defining subtags seems 
to be gone:

    Language-Tag  = langtag
                  / privateuse             ; private use tag
                  / grandfathered          ; grandfathered registrations

    langtag       = (language
                     ["-" script]
                     ["-" region]
                     *("-" variant)
                     *("-" extension)
                     ["-" privateuse])

    language      = (2*3ALPHA [ extlang ]) ; shortest ISO 639 code
                  / 4ALPHA                 ; reserved for future use
                  / 5*8ALPHA               ; registered language subtag

    extlang       = *3("-" 3ALPHA)         ; reserved for future use

    script        = 4ALPHA                 ; ISO 15924 code

    region        = 2ALPHA                 ; ISO 3166 code
                  / 3DIGIT                 ; UN M.49 code

    variant       = 5*8alphanum            ; registered variants
                  / (DIGIT 3alphanum)

    extension     = singleton 1*("-" (2*8alphanum))

    singleton     = %x41-57 / %x59-5A / %x61-77 / %x79-7A / DIGIT
                  ; "a"-"w" / "y"-"z" / "A"-"W" / "Y"-"Z" / "0"-"9"
                  ; Single letters: x/X is reserved for private use

    privateuse    = ("x"/"X") 1*("-" (1*8alphanum))

    grandfathered = 1*3ALPHA 1*2("-" (2*8alphanum))
                    ; grandfathered registration
                    ; Note: i is the only singleton
                    ; that starts a grandfathered tag

    alphanum      = (ALPHA / DIGIT)       ; letters and numbers

(<http://tools.ietf.org/html/rfc4646#page-5>).

So shouldn't RFC2616 (Section 3.10) stop defining these things, and just 
normatively refer to RFC4626 for the definition of "Language-Tag"?

Best regards, Julian
Received on Saturday, 14 October 2006 12:13:49 GMT

This archive was generated by hypermail 2.2.0+W3C-0.50 : Friday, 27 April 2012 06:49:53 GMT